adjoint_output.f90

Go to the documentation of this file.

 
!
module adjoint_output
  use num_types, only: rp
  use adjoint_fluid_scheme, only: adjoint_fluid_scheme_t
  use scalar_scheme, only: scalar_scheme_t
  use adjoint_scalar_scheme, only: adjoint_scalar_scheme_t
  use field_list, only: field_list_t
  use neko_config, only: neko_bcknd_device
  use device, only: device_memcpy, device_to_host
  use output, only: output_t
  use adjoint_scalars, only : adjoint_scalars_t
  use fld_file, only: fld_file_t
  implicit none
  private
 
  type, public, extends(output_t) :: adjoint_output_t
     type(field_list_t) :: adjoint
     logical :: always_write_mesh = .false.
   contains
     procedure, pass(this) :: init => adjoint_output_init
     procedure, pass(this) :: free => adjoint_output_free
     procedure, pass(this) :: sample => adjoint_output_sample
  end type adjoint_output_t
 
contains
 
  subroutine adjoint_output_init(this, precision, adjoint, adjoint_scalars, &
       name, path, fmt, layout, always_write_mesh)
    class(adjoint_output_t), intent(inout) :: this
    integer, intent(in) :: precision
    class(adjoint_fluid_scheme_t), intent(in), target :: adjoint
    class(adjoint_scalars_t), intent(in), optional, target :: adjoint_scalars
    character(len=*), intent(in), optional :: name
    character(len=*), intent(in), optional :: path
    character(len=*), intent(in), optional :: fmt
    logical, intent(in), optional :: always_write_mesh
    integer, intent(in), optional :: layout
    character(len=1024) :: fname, suffix
    integer :: i, n_scalars
 
    call this%free()
 
    suffix = '.fld'
    if (present(fmt)) then
       if (fmt .eq. 'adios2') then
          suffix = '.bp'
       else if (fmt .eq. 'vtkhdf') then
          suffix = '.vtkhdf'
       end if
    end if
 
    if (present(always_write_mesh)) then
       this%always_write_mesh = always_write_mesh
    end if
 
    if (present(name) .and. present(path)) then
       fname = trim(path) // trim(name) // trim(suffix)
    else if (present(name)) then
       fname = trim(name) // trim(suffix)
    else if (present(path)) then
       fname = trim(path) // 'field' // trim(suffix)
    else
       fname = 'field' // trim(suffix)
    end if
 
    if (present(layout)) then
       call this%init_base(fname, precision, layout)
    else
       call this%init_base(fname, precision)
    end if
 
    ! Calculate total number of fields
    n_scalars = 0
    if (present(adjoint_scalars)) then
       n_scalars = size(adjoint_scalars%adjoint_scalar_fields)
    end if
 
    ! Initialize field list with appropriate size
    call this%adjoint%init(4 + n_scalars)
 
    call this%adjoint%assign(1, adjoint%p_adj)
    call this%adjoint%assign(2, adjoint%u_adj)
    call this%adjoint%assign(3, adjoint%v_adj)
    call this%adjoint%assign(4, adjoint%w_adj)
 
    ! Assign all scalar fields
    if (present(adjoint_scalars)) then
       do i = 1, n_scalars
          call this%adjoint%assign(4 + i, &
               adjoint_scalars%adjoint_scalar_fields(i)%s_adj)
       end do
    end if
 
  end subroutine adjoint_output_init
 
  subroutine adjoint_output_free(this)
    class(adjoint_output_t), intent(inout) :: this
 
    call this%free_base()
    call this%adjoint%free()
 
  end subroutine adjoint_output_free
 
  subroutine adjoint_output_sample(this, t)
    class(adjoint_output_t), intent(inout) :: this
    real(kind=rp), intent(in) :: t
    integer :: i
 
    if (neko_bcknd_device .eq. 1) then
 
       associate(fields => this%adjoint%items)
         do i = 1, size(fields)
            call device_memcpy(fields(i)%ptr%x, fields(i)%ptr%x_d, &
                 fields(i)%ptr%dof%size(), device_to_host, &
                 sync = (i .eq. size(fields))) ! Sync on the last field
         end do
       end associate
 
    end if
 
    select type (ft => this%file_%file_type)
       ! Only fld files have the option to write the mesh at command
    type is (fld_file_t)
       ft%write_mesh = this%always_write_mesh
       call ft%write(this%adjoint, t)
    class default
       call ft%write(this%adjoint, t)
    end select
 
  end subroutine adjoint_output_sample
 
end module adjoint_output