linear_mapping.f90

Go to the documentation of this file.

 
!
module linear_mapping
  use num_types, only: rp
  use field_math, only: field_copy, field_cmult, field_cadd
  use mapping, only: mapping_t
  use num_types, only: rp
  use json_module, only: json_file
  use field, only: field_t
  use coefs, only: coef_t
  use json_utils, only: json_get, json_get_or_default
  implicit none
  private
 
  type, public, extends(mapping_t) :: linear_mapping_t
     real(kind=rp) :: f_min
     real(kind=rp) :: f_max
 
   contains
     procedure, pass(this) :: init => linear_mapping_init_from_json
     procedure, pass(this) :: init_from_attributes => &
          linear_mapping_init_from_attributes
     procedure, pass(this) :: free => linear_mapping_free
     procedure, pass(this) :: forward_mapping => linear_forward_mapping
     procedure, pass(this) :: backward_mapping => &
          linear_backward_mapping
  end type linear_mapping_t
 
contains
 
  subroutine linear_mapping_init_from_json(this, json, coef)
    class(linear_mapping_t), intent(inout) :: this
    type(json_file), intent(inout) :: json
    type(coef_t), intent(inout) :: coef
    real(kind=rp) :: f_min, f_max
 
    call json_get_or_default(json, 'f_min', f_min, 0.0_rp)
    call json_get(json, 'f_max', f_max)
 
    call this%init_base(json, coef)
    call linear_mapping_init_from_attributes(this, coef, f_min, f_max)
 
  end subroutine linear_mapping_init_from_json
 
  subroutine linear_mapping_init_from_attributes(this, coef, f_min, f_max)
    class(linear_mapping_t), intent(inout) :: this
    type(coef_t), intent(inout) :: coef
    real(kind=rp), intent(in) :: f_min, f_max
 
    this%f_min = f_min
    this%f_max = f_max
 
  end subroutine linear_mapping_init_from_attributes
 
  subroutine linear_mapping_free(this)
    class(linear_mapping_t), intent(inout) :: this
 
    call this%free_base()
 
  end subroutine linear_mapping_free
 
  subroutine linear_forward_mapping(this, X_out, X_in)
    class(linear_mapping_t), intent(inout) :: this
    type(field_t), intent(in) :: X_in
    type(field_t), intent(inout) :: X_out
 
    ! x_out = f_min + (f_max - f_min) * x_in
    call field_copy(x_out, x_in)
    call field_cmult(x_out, this%f_max - this%f_min)
    call field_cadd(x_out, this%f_min)
 
  end subroutine linear_forward_mapping
 
 
  subroutine linear_backward_mapping(this, sens_out, sens_in, X_in)
    class(linear_mapping_t), intent(inout) :: this
    type(field_t), intent(in) :: X_in
    type(field_t), intent(in) :: sens_in
    type(field_t), intent(inout) :: sens_out
 
    ! df/dx_in = df/dx_out * dx_out/dx_in
 
    ! dx_out/dx_in = (f_max - f_min)
 
    call field_copy(sens_out, sens_in)
    call field_cmult(sens_out, this%f_max - this%f_min)
 
  end subroutine linear_backward_mapping
 
end module linear_mapping