mapping.f90

Go to the documentation of this file.

 
!
module mapping
  use num_types, only: rp
  use json_module, only: json_file
  use coefs, only: coef_t
  use field, only: field_t
  use field_math, only: field_copy
  use registry, only: neko_registry
  implicit none
  private
 
  type, abstract, public :: mapping_t
     type(coef_t), pointer :: coef => null()
     type(field_t), pointer :: x_in => null()
     character(len=80) :: fld_name = ""
 
   contains
     procedure, pass(this) :: init_base => mapping_init_base
     procedure, pass(this) :: free_base => mapping_free_base
     procedure, pass(this) :: apply_forward => mapping_apply_forward_wrapper
     procedure, pass(this) :: apply_backward => mapping_apply_backward_wrapper
     procedure(mapping_init), pass(this), deferred :: init
     procedure(mapping_free), pass(this), deferred :: free
     procedure(mapping_forward_mapping), pass(this), deferred :: forward_mapping
     procedure(mapping_backward_mapping), pass(this), deferred :: &
          backward_mapping
  end type mapping_t
 
  type, public :: mapping_wrapper_t
     class(mapping_t), allocatable :: mapping
   contains
     procedure, pass(this) :: free => mapping_wrapper_free
  end type mapping_wrapper_t
 
  abstract interface
 
     subroutine mapping_init(this, json, coef)
       import mapping_t, json_file, coef_t
       class(mapping_t), intent(inout) :: this
       type(json_file), intent(inout) :: json
       type(coef_t), intent(inout) :: coef
     end subroutine mapping_init
  end interface
 
  abstract interface
 
     subroutine mapping_free(this)
       import mapping_t
       class(mapping_t), intent(inout) :: this
     end subroutine mapping_free
  end interface
 
  abstract interface
 
     subroutine mapping_forward_mapping(this, X_out, X_in)
       import mapping_t, field_t
       class(mapping_t), intent(inout) :: this
       type(field_t), intent(in) :: X_in
       type(field_t), intent(inout) :: X_out
     end subroutine mapping_forward_mapping
  end interface
 
  abstract interface
 
     subroutine mapping_backward_mapping(this, sens_out, sens_in, X_in)
       import mapping_t, field_t
       class(mapping_t), intent(inout) :: this
       type(field_t), intent(in) :: sens_in
       type(field_t), intent(in) :: X_in
       type(field_t), intent(inout) :: sens_out
     end subroutine mapping_backward_mapping
  end interface
 
  interface mapping_factory
     module subroutine mapping_factory(object, json, coef)
       class(mapping_t), allocatable, intent(inout) :: object
       type(json_file), intent(inout) :: json
       type(coef_t), intent(inout) :: coef
     end subroutine mapping_factory
  end interface mapping_factory
 
  public :: mapping_factory
contains
 
  subroutine mapping_init_base(this, json, coef, fld_name)
    class(mapping_t), intent(inout) :: this
    type(json_file), intent(inout) :: json
    character(len=*), intent(in) :: fld_name
    type(coef_t), intent(inout), target :: coef
 
    this%coef => coef
    this%fld_name = fld_name
    ! The mapping handler will take care of naming this field
    call neko_registry%add_field(coef%dof, this%fld_name)
    this%X_in => neko_registry%get_field(this%fld_name)
 
  end subroutine mapping_init_base
 
  subroutine mapping_free_base(this)
    class(mapping_t), intent(inout) :: this
 
    nullify(this%X_in)
    nullify(this%coef)
 
  end subroutine mapping_free_base
 
  subroutine mapping_wrapper_free(this)
    class(mapping_wrapper_t), intent(inout) :: this
 
    if (allocated(this%mapping)) then
       call this%mapping%free()
       deallocate(this%mapping)
    end if
  end subroutine mapping_wrapper_free
 
  subroutine mapping_apply_forward_wrapper(this, X_out, X_in)
    class(mapping_t), intent(inout) :: this
    type(field_t), intent(inout) :: X_out
    type(field_t), intent(in) :: X_in
 
    call field_copy(this%X_in, x_in)
    call this%forward_mapping(x_out, this%X_in)
 
  end subroutine mapping_apply_forward_wrapper
 
  subroutine mapping_apply_backward_wrapper(this, sens_out, sens_in)
    class(mapping_t), intent(inout) :: this
    type(field_t), intent(inout) :: sens_out
    type(field_t), intent(in) :: sens_in
    ! @todo
    ! hmmmm, it would be silly to call mapping backward without mapping forward
    ! but at least this%X_in is certainly initialized.
    ! but it won't contain the correct information unless a map forward has
    ! occured.
    call this%backward_mapping(sens_out, sens_in, this%X_in)
 
  end subroutine mapping_apply_backward_wrapper
 
end module mapping