constraint.f90

Go to the documentation of this file.

 
 
module constraint
  use base_functional, only: base_functional_t
  use simulation_m, only: simulation_t
  use design, only: design_t
  use num_types, only: rp
  use point_zone_registry, only: neko_point_zone_registry
  use json_module, only: json_file
  implicit none
  private
 
  public :: constraint_t, constraint_factory, constraint_wrapper_t
 
  type, abstract, extends(base_functional_t) :: constraint_t
   contains
 
     procedure, pass(this) :: init_base => constraint_init_base
     procedure, pass(this) :: free_base => constraint_free_base
 
  end type constraint_t
 
  type :: constraint_wrapper_t
     class(constraint_t), allocatable :: constraint
   contains
     procedure, pass(this) :: free => constraint_wrapper_free
  end type constraint_wrapper_t
 
  ! -------------------------------------------------------------------------- !
  ! Explicit interfaces
 
  interface constraint_factory
     module subroutine constraint_factory(object, json, design, simulation)
       class(constraint_t), allocatable, intent(inout) :: object
       type(json_file), intent(inout) :: json
       class(design_t), intent(in) :: design
       type(simulation_t), target, optional, intent(inout) :: simulation
     end subroutine constraint_factory
  end interface constraint_factory
 
contains
 
  ! -------------------------------------------------------------------------- !
  ! Implementations for the base class
 
  subroutine constraint_init_base(this, name, design_size, mask_name, &
       start_time, end_time)
    class(constraint_t), intent(inout) :: this
    character(len=*), intent(in) :: name
    integer, intent(in) :: design_size
    character(len=*), intent(in), optional :: mask_name
    real(kind=rp), intent(in), optional :: start_time
    real(kind=rp), intent(in), optional :: end_time
 
    call this%free_base()
 
    this%name = name
    call this%sensitivity%init(design_size)
    call this%sensitivity_old%init(design_size)
 
    if (present(mask_name)) then
       if (mask_name .ne. "") then
          this%has_mask = .true.
          this%mask => neko_point_zone_registry%get_point_zone(mask_name)
       end if
    end if
 
    if (present(start_time)) then
       this%start_time = start_time
    else
       this%start_time = 0.0_rp
    end if
 
    if (present(end_time)) then
       this%end_time = end_time
    else
       this%end_time = huge(0.0_rp)
    end if
 
  end subroutine constraint_init_base
 
  subroutine constraint_free_base(this)
    class(constraint_t), target, intent(inout) :: this
 
    this%name = ""
 
    this%value = 0.0_rp
    this%value_old = 0.0_rp
    this%start_time = 0.0_rp
    this%end_time = huge(0.0_rp)
    call this%sensitivity%free()
    call this%sensitivity_old%free()
 
    this%has_mask = .false.
    if (associated(this%mask)) nullify(this%mask)
 
  end subroutine constraint_free_base
 
  ! -------------------------------------------------------------------------- !
  ! Implementations for the wrapper
 
  subroutine constraint_wrapper_free(this)
    class(constraint_wrapper_t), intent(inout) :: this
    if (allocated(this%constraint)) then
       call this%constraint%free()
       deallocate(this%constraint)
    end if
  end subroutine constraint_wrapper_free
 
end module constraint