state_recover_fctry.f90

 
!
submodule(state_recover) state_recover_fctry
  use json_utils, only: json_get_or_default
  use state_recover_checkpoint, only: state_recover_checkpoint_t
  use utils, only: neko_error
  implicit none
 
contains
 
  module subroutine state_recover_factory(recover, neko_case, params)
    class(state_recover_t), allocatable, intent(inout) :: recover
    class(case_t), target, intent(inout) :: neko_case
    type(json_file), intent(inout) :: params
    character(len=:), allocatable :: recover_type
 
    call json_get_or_default(params, "type", recover_type, "checkpoint")
    call state_recover_allocator(recover, recover_type)
    call recover%init(neko_case, params)
  end subroutine state_recover_factory
 
  subroutine state_recover_allocator(recover, recover_type)
    class(state_recover_t), allocatable, intent(inout) :: recover
    character(len=*), intent(in) :: recover_type
 
    if (allocated(recover)) then
       call recover%free()
       deallocate(recover)
    end if
 
    select case (trim(recover_type))
    case ("checkpoint", "simulation_checkpoint")
       allocate(state_recover_checkpoint_t :: recover)
    case default
       call neko_error("Unknown state recover type: " // trim(recover_type))
    end select
 
  end subroutine state_recover_allocator
 
end submodule state_recover_fctry