Borrvall_Petersson_mapping.f90

Go to the documentation of this file.

 
!
module borrvall_petersson_mapping
  use num_types, only: rp
  use mapping, only: mapping_t
  use json_module, only: json_file
  use field, only: field_t
  use coefs, only: coef_t
  use neko_config, only: neko_bcknd_device
  use device_borrvall_petersson_mapping, only: &
       device_borrvall_petersson_mapping_apply, &
       device_borrvall_petersson_mapping_apply_backward
  use borrvall_petersson_mapping_cpu, only: &
       borrvall_petersson_mapping_apply_cpu, &
       borrvall_petersson_mapping_apply_backward_cpu
  use json_utils, only: json_get, json_get_or_default
  use logger, only: neko_log
  use continuation_scheduler, only: nekotop_continuation
  implicit none
  private
 
 
  type, public, extends(mapping_t) :: borrvall_petersson_mapping_t
     real(kind=rp) :: f_min
     real(kind=rp) :: f_max
     real(kind=rp) :: q
 
   contains
     procedure, pass(this) :: init => borrvall_petersson_mapping_init_from_json
     procedure, pass(this) :: init_from_attributes => &
          borrvall_petersson_mapping_init_from_attributes
     procedure, pass(this) :: free => borrvall_petersson_mapping_free
     procedure, pass(this) :: forward_mapping => &
          borrvall_petersson_forward_mapping
     procedure, pass(this) :: backward_mapping => &
          borrvall_petersson_backward_mapping
  end type borrvall_petersson_mapping_t
 
contains
 
  subroutine borrvall_petersson_mapping_init_from_json(this, json, coef)
    class(borrvall_petersson_mapping_t), intent(inout) :: this
    type(json_file), intent(inout) :: json
    type(coef_t), intent(inout) :: coef
    real(kind=rp) :: f_min, f_max, q
 
    call json_get_or_default(json, 'f_min', f_min, 0.0_rp)
    call nekotop_continuation%json_get_or_register(json, 'f_max', this%f_max, &
         f_max)
    call nekotop_continuation%json_get_or_register(json, 'q', this%q, q, 1.0_rp)
 
    call this%init_base(json, coef, "Borrvall_Petersson_mapping")
    call this%init_from_attributes(coef, f_min, f_max, q)
 
  end subroutine borrvall_petersson_mapping_init_from_json
 
  subroutine borrvall_petersson_mapping_init_from_attributes(this, coef, &
       f_min, f_max, q)
    class(borrvall_petersson_mapping_t), intent(inout) :: this
    type(coef_t), intent(inout) :: coef
    real(kind=rp), intent(in) :: f_min, f_max, q
    character(len=256) :: msg
 
    this%f_min = f_min
    this%f_max = f_max
    this%q = q
 
    call neko_log%section('Borrvall & Petersson Mapping')
    write(msg, '(A,F8.4)') '  f_min: ', this%f_min
    call neko_log%message(msg)
    write(msg, '(A,F8.4)') '  f_max: ', this%f_max
    call neko_log%message(msg)
    write(msg, '(A,F8.4)') '  q:     ', this%q
    call neko_log%message(msg)
    call neko_log%end_section()
 
  end subroutine borrvall_petersson_mapping_init_from_attributes
 
  subroutine borrvall_petersson_mapping_free(this)
    class(borrvall_petersson_mapping_t), intent(inout) :: this
 
    call this%free_base()
 
  end subroutine borrvall_petersson_mapping_free
 
  subroutine borrvall_petersson_forward_mapping(this, X_out, X_in)
    class(borrvall_petersson_mapping_t), intent(inout) :: this
    type(field_t), intent(in) :: X_in
    type(field_t), intent(inout) :: X_out
    integer :: n
 
    ! The moved (unmodified) kernel computes
    !   arg1 + (arg2 - arg1) * S(x)
    ! with S(x) = x (q+1) / (x+q). Passing f_max as arg1 and f_min as arg2
    ! (i.e. SWAPPED with respect to the historic RAMP call) yields the correct
    ! Borrvall & Petersson assembly
    !   f(x) = f_max + (f_min - f_max) * S(x).
    n = x_in%dof%size()
    if (neko_bcknd_device .eq. 1) then
       call device_borrvall_petersson_mapping_apply(this%f_max, this%f_min, &
            this%q, x_out%x_d, x_in%x_d, n)
    else
       call borrvall_petersson_mapping_apply_cpu(this%f_max, this%f_min, &
            this%q, x_out%x, x_in%x, n)
    end if
 
  end subroutine borrvall_petersson_forward_mapping
 
 
  subroutine borrvall_petersson_backward_mapping(this, sens_out, sens_in, X_in)
    class(borrvall_petersson_mapping_t), intent(inout) :: this
    type(field_t), intent(in) :: X_in
    type(field_t), intent(in) :: sens_in
    type(field_t), intent(inout) :: sens_out
    integer :: n
 
    ! Same SWAP of f_min/f_max as the forward mapping. The moved kernel gives
    !   dx_out/dx_in = (arg2 - arg1) * (q+1) * q / (x+q)**2
    ! which with arg1 = f_max, arg2 = f_min becomes
    !   f'(x) = q (q+1) (f_min - f_max) / (x+q)**2.
    n = x_in%dof%size()
    if (neko_bcknd_device .eq. 1) then
       call device_borrvall_petersson_mapping_apply_backward(this%f_max, &
            this%f_min, this%q, sens_out%x_d, sens_in%x_d, x_in%x_d, n)
    else
       call borrvall_petersson_mapping_apply_backward_cpu(this%f_max, &
            this%f_min, this%q, sens_out%x, sens_in%x, x_in%x, n)
    end if
 
  end subroutine borrvall_petersson_backward_mapping
 
end module borrvall_petersson_mapping