heaviside_mapping.f90

Go to the documentation of this file.

 
!
module heaviside_mapping
  use num_types, only: rp
  use mapping, only: mapping_t
  use json_module, only: json_file
  use field, only: field_t
  use coefs, only: coef_t
  use neko_config, only: neko_bcknd_device
  use device_heaviside_mapping, only: &
       device_heaviside_mapping_apply, &
       device_heaviside_mapping_apply_backward
  use heaviside_mapping_cpu, only: &
       heaviside_mapping_apply_cpu, &
       heaviside_mapping_apply_backward_cpu
  use json_utils, only: json_get, json_get_or_default
  use utils, only: neko_error
  implicit none
  private
 
  type, public, extends(mapping_t) :: heaviside_mapping_t
     real(kind=rp) :: beta
     real(kind=rp) :: eta
 
   contains
     procedure, pass(this) :: init => heaviside_mapping_init_from_json
     procedure, pass(this) :: init_from_attributes => &
          heaviside_mapping_init_from_attributes
     procedure, pass(this) :: free => heaviside_mapping_free
     procedure, pass(this) :: forward_mapping => heaviside_mapping_forward
     procedure, pass(this) :: backward_mapping => heaviside_mapping_backward
  end type heaviside_mapping_t
 
contains
 
  subroutine heaviside_mapping_init_from_json(this, json, coef)
    class(heaviside_mapping_t), intent(inout) :: this
    type(json_file), intent(inout) :: json
    type(coef_t), intent(inout) :: coef
    real(kind=rp) :: beta, eta
 
    call json_get(json, 'beta', beta)
    call json_get_or_default(json, 'eta', eta, 0.5_rp)
 
    call this%init_base(json, coef)
    call this%init_from_attributes(coef, beta, eta)
  end subroutine heaviside_mapping_init_from_json
 
  subroutine heaviside_mapping_init_from_attributes(this, coef, beta, eta)
    class(heaviside_mapping_t), intent(inout) :: this
    type(coef_t), intent(inout) :: coef
    real(kind=rp), intent(in) :: beta
    real(kind=rp), intent(in) :: eta
 
    if (beta .le. 0.0_rp) then
       call neko_error('"beta" must be > 0 in heaviside mapping')
    end if
 
    if (eta .lt. 0.0_rp .or. eta .gt. 1.0_rp) then
       call neko_error('"eta" must be in [0, 1] in heaviside mapping')
    end if
 
    this%beta = beta
    this%eta = eta
  end subroutine heaviside_mapping_init_from_attributes
 
  subroutine heaviside_mapping_free(this)
    class(heaviside_mapping_t), intent(inout) :: this
 
    call this%free_base()
  end subroutine heaviside_mapping_free
 
  subroutine heaviside_mapping_forward(this, X_out, X_in)
    class(heaviside_mapping_t), intent(inout) :: this
    type(field_t), intent(in) :: X_in
    type(field_t), intent(inout) :: X_out
    call heaviside_mapping_apply(this%beta, this%eta, x_out, x_in)
  end subroutine heaviside_mapping_forward
 
  subroutine heaviside_mapping_backward(this, sens_out, sens_in, X_in)
    class(heaviside_mapping_t), intent(inout) :: this
    type(field_t), intent(in) :: X_in
    type(field_t), intent(in) :: sens_in
    type(field_t), intent(inout) :: sens_out
    call heaviside_mapping_apply_backward(this%beta, this%eta, &
         sens_out, sens_in, x_in)
  end subroutine heaviside_mapping_backward
 
  subroutine heaviside_mapping_apply(beta, eta, X_out, X_in)
    real(kind=rp), intent(in) :: beta, eta
    type(field_t), intent(in) :: x_in
    type(field_t), intent(inout) :: X_out
    integer :: n
    real(kind=rp) :: den, beta_eta
 
    beta_eta = beta * eta
    den = tanh(beta_eta) + tanh(beta * (1.0_rp - eta))
 
    if (abs(den) .le. tiny(den)) then
       call neko_error('invalid denominator in heaviside mapping')
    end if
 
    n = x_in%dof%size()
    if (neko_bcknd_device .eq. 1) then
       call device_heaviside_mapping_apply(beta, eta, &
            x_out%x_d, x_in%x_d, n)
    else
       call heaviside_mapping_apply_cpu(beta, eta, &
            x_out%x, x_in%x, n)
    end if
  end subroutine heaviside_mapping_apply
 
  subroutine heaviside_mapping_apply_backward(beta, eta, sens_out, sens_in, &
       X_in)
    real(kind=rp), intent(in) :: beta, eta
    type(field_t), intent(in) :: x_in
    type(field_t), intent(in) :: sens_in
    type(field_t), intent(inout) :: sens_out
    integer :: n
    real(kind=rp) :: den, beta_eta
 
    beta_eta = beta * eta
    den = tanh(beta_eta) + tanh(beta * (1.0_rp - eta))
 
    if (abs(den) .le. tiny(den)) then
       call neko_error('invalid denominator in heaviside mapping')
    end if
 
    n = x_in%dof%size()
    if (neko_bcknd_device .eq. 1) then
       call device_heaviside_mapping_apply_backward(beta, eta, &
            sens_out%x_d, sens_in%x_d, x_in%x_d, n)
    else
       call heaviside_mapping_apply_backward_cpu(beta, eta, &
            sens_out%x, sens_in%x, x_in%x, n)
    end if
  end subroutine heaviside_mapping_apply_backward
 
end module heaviside_mapping