SIMP_mapping.f90

! Copyright (c) 2023, The Neko Authors
! All rights reserved.
!
! Redistribution and use in source and binary forms, with or without
! modification, are permitted provided that the following conditions
! are met:
!
!   * Redistributions of source code must retain the above copyright
!     notice, this list of conditions and the following disclaimer.
!
!   * Redistributions in binary form must reproduce the above
!     copyright notice, this list of conditions and the following
!     disclaimer in the documentation and/or other materials provided
!     with the distribution.
!
!   * Neither the name of the authors nor the names of its
!     contributors may be used to endorse or promote products derived
!     from this software without specific prior written permission.
!
! THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
! "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
! LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
! FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
! COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
! INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
! BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
! LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
! CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
! LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
! ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
! POSSIBILITY OF SUCH DAMAGE.
!
!
module simp_mapping
  use num_types, only: rp
  use mapping, only: mapping_t
  use json_module, only: json_file
  use field, only: field_t
  use coefs, only: coef_t
  use neko_config, only: neko_bcknd_device
  use device_simp_mapping, only: device_simp_mapping_apply, &
       device_simp_mapping_apply_backward
  use simp_mapping_cpu, only: simp_mapping_apply_cpu, &
       simp_mapping_apply_backward_cpu
  use json_utils, only: json_get, json_get_or_default
  implicit none
  private
 
 
  type, public, extends(mapping_t) :: simp_mapping_t
     real(kind=rp) :: f_min
     real(kind=rp) :: f_max
     real(kind=rp) :: p
 
   contains
     procedure, pass(this) :: init => simp_mapping_init_from_json
     procedure, pass(this) :: init_from_attributes => &
          simp_mapping_init_from_attributes
     procedure, pass(this) :: free => simp_mapping_free
     procedure, pass(this) :: forward_mapping => simp_forward_mapping
     procedure, pass(this) :: backward_mapping => simp_backward_mapping
  end type simp_mapping_t
 
contains
 
  subroutine simp_mapping_init_from_json(this, json, coef)
    class(simp_mapping_t), intent(inout) :: this
    type(json_file), intent(inout) :: json
    type(coef_t), intent(inout) :: coef
    real(kind=rp) :: f_min, f_max, p
 
    call json_get_or_default(json, 'f_min', f_min, 0.0_rp)
    call json_get(json, 'f_max', f_max)
    call json_get_or_default(json, 'p', p, 1.0_rp)
 
    call this%init_base(json, coef)
    call this%init_from_attributes(coef, f_min, f_max, p)
 
  end subroutine simp_mapping_init_from_json
 
  subroutine simp_mapping_init_from_attributes(this, coef, f_min, f_max, p)
    class(simp_mapping_t), intent(inout) :: this
    type(coef_t), intent(inout) :: coef
    real(kind=rp), intent(in) :: f_min, f_max, p
 
    this%f_min = f_min
    this%f_max = f_max
    this%p = p
 
  end subroutine simp_mapping_init_from_attributes
 
  subroutine simp_mapping_free(this)
    class(simp_mapping_t), intent(inout) :: this
 
    call this%free_base()
 
  end subroutine simp_mapping_free
 
  subroutine simp_forward_mapping(this, X_out, X_in)
    class(simp_mapping_t), intent(inout) :: this
    type(field_t), intent(in) :: X_in
    type(field_t), intent(inout) :: X_out
    integer :: n
 
    n = x_in%dof%size()
    if (neko_bcknd_device .eq. 1) then
       call device_simp_mapping_apply(this%f_min, this%f_max, this%p, &
            x_out%x_d, x_in%x_d, n)
    else
       call simp_mapping_apply_cpu(this%f_min, this%f_max, this%p, &
            x_out%x, x_in%x, n)
    end if
 
  end subroutine simp_forward_mapping
 
 
  subroutine simp_backward_mapping(this, sens_out, sens_in, X_in)
    class(simp_mapping_t), intent(inout) :: this
    type(field_t), intent(in) :: X_in
    type(field_t), intent(in) :: sens_in
    type(field_t), intent(inout) :: sens_out
    integer :: n
 
    n = x_in%dof%size()
    if (neko_bcknd_device .eq. 1) then
       call device_simp_mapping_apply_backward(this%f_min, this%f_max, this%p, &
            sens_out%x_d, sens_in%x_d, x_in%x_d, n)
    else
       call simp_mapping_apply_backward_cpu(this%f_min, this%f_max, this%p, &
            sens_out%x, sens_in%x, x_in%x, n)
    end if
 
  end subroutine simp_backward_mapping
 
end module simp_mapping