RAMP_mapping.f90

Go to the documentation of this file.

 
!
module ramp_mapping
  use num_types, only: rp
  use mapping, only: mapping_t
  use json_module, only: json_file
  use field, only: field_t
  use coefs, only: coef_t
  use neko_config, only: neko_bcknd_device
  use device_ramp_mapping, only: device_convex_down_ramp_mapping_apply, &
       device_convex_down_ramp_mapping_apply_backward
  use ramp_mapping_cpu, only: convex_down_ramp_mapping_apply_cpu, &
       convex_down_ramp_mapping_apply_backward_cpu
  use json_utils, only: json_get, json_get_or_default
  use logger, only: neko_log
  use utils, only: neko_error
  use continuation_scheduler, only: nekotop_continuation
  implicit none
  private
 
 
  type, public, extends(mapping_t) :: ramp_mapping_t
     real(kind=rp) :: f_min
     real(kind=rp) :: f_max
     real(kind=rp) :: q
 
   contains
     procedure, pass(this) :: init => ramp_mapping_init_from_json
     procedure, pass(this) :: init_from_attributes => &
          ramp_mapping_init_from_attributes
     procedure, pass(this) :: free => ramp_mapping_free
     procedure, pass(this) :: forward_mapping => ramp_forward_mapping
     procedure, pass(this) :: backward_mapping => ramp_backward_mapping
  end type ramp_mapping_t
 
contains
 
  subroutine ramp_mapping_init_from_json(this, json, coef)
    class(ramp_mapping_t), intent(inout) :: this
    type(json_file), intent(inout) :: json
    type(coef_t), intent(inout) :: coef
    real(kind=rp) :: f_min, f_max, q
 
    ! The 'convex_up' option has been removed. Fail loud rather than silently
    ! reinterpreting old case files.
    if (json%valid_path('convex_up')) then
       call neko_error("RAMP mapping's 'convex_up' option has been " // &
            "removed -- plain RAMP is now always the down/increasing form " // &
            "(x=0:fluid, x=1:solid). For the x=0:solid/x=1:fluid form, " // &
            "use type 'Borrvall_Petersson' instead.")
    end if
 
    call json_get_or_default(json, 'f_min', f_min, 0.0_rp)
    call nekotop_continuation%json_get_or_register(json, 'f_max', this%f_max, &
         f_max)
    call nekotop_continuation%json_get_or_register(json, 'q', this%q, q, 1.0_rp)
 
    call this%init_base(json, coef, "RAMP_mapping")
    call this%init_from_attributes(coef, f_min, f_max, q)
 
  end subroutine ramp_mapping_init_from_json
 
  subroutine ramp_mapping_init_from_attributes(this, coef, f_min, f_max, q)
    class(ramp_mapping_t), intent(inout) :: this
    type(coef_t), intent(inout) :: coef
    real(kind=rp), intent(in) :: f_min, f_max, q
    character(len=256) :: msg
 
    this%f_min = f_min
    this%f_max = f_max
    this%q = q
 
    call neko_log%section('RAMP Mapping')
    write(msg, '(A,F8.4)') '  f_min: ', this%f_min
    call neko_log%message(msg)
    write(msg, '(A,F8.4)') '  f_max: ', this%f_max
    call neko_log%message(msg)
    write(msg, '(A,F8.4)') '  q:     ', this%q
    call neko_log%message(msg)
    call neko_log%end_section()
 
  end subroutine ramp_mapping_init_from_attributes
 
  subroutine ramp_mapping_free(this)
    class(ramp_mapping_t), intent(inout) :: this
 
    call this%free_base()
 
  end subroutine ramp_mapping_free
 
  subroutine ramp_forward_mapping(this, X_out, X_in)
    class(ramp_mapping_t), intent(inout) :: this
    type(field_t), intent(in) :: X_in
    type(field_t), intent(inout) :: X_out
 
    call convex_down_ramp_mapping_apply(this%f_min, this%f_max, &
         this%q, x_out, x_in)
 
  end subroutine ramp_forward_mapping
 
 
  subroutine ramp_backward_mapping(this, sens_out, sens_in, X_in)
    class(ramp_mapping_t), intent(inout) :: this
    type(field_t), intent(in) :: X_in
    type(field_t), intent(in) :: sens_in
    type(field_t), intent(inout) :: sens_out
 
    call convex_down_ramp_mapping_apply_backward(this%f_min, this%f_max, &
         this%q, sens_out, sens_in, x_in)
 
  end subroutine ramp_backward_mapping
 
  subroutine convex_down_ramp_mapping_apply(f_min, f_max, q, X_out, X_in)
    real(kind=rp), intent(in) :: q, f_min, f_max
    type(field_t), intent(in) :: x_in
    type(field_t), intent(inout) :: X_out
    integer :: n
 
    ! x_out = f_min + (f_max - f_min) * x_in / (1 + q * (1 - x_in) )
 
    n = x_in%dof%size()
    if (neko_bcknd_device .eq. 1) then
       call device_convex_down_ramp_mapping_apply(f_min, f_max, q, &
            x_out%x_d, x_in%x_d, n)
    else
       call convex_down_ramp_mapping_apply_cpu(f_min, f_max, q, &
            x_out%x, x_in%x, n)
    end if
 
  end subroutine convex_down_ramp_mapping_apply
 
 
  subroutine convex_down_ramp_mapping_apply_backward(f_min, f_max, q, &
       sens_out, sens_in, X_in)
    real(kind=rp), intent(in) :: f_min, f_max, q
    type(field_t), intent(in) :: x_in
    type(field_t), intent(in) :: sens_in
    type(field_t), intent(inout) :: sens_out
    integer :: n
 
    ! df/dx_in = df/dx_out * dx_out/dx_in
 
    ! dx_out/dx_in = (f_max - f_min) * (q + 1) / (1 - q*(x - 1))**2
 
    n = x_in%dof%size()
 
    if (neko_bcknd_device .eq. 1) then
       call device_convex_down_ramp_mapping_apply_backward(f_min, f_max, q, &
            sens_out%x_d, sens_in%x_d, x_in%x_d, n)
    else
       call convex_down_ramp_mapping_apply_backward_cpu(f_min, f_max, q, &
            sens_out%x, sens_in%x, x_in%x, n)
    end if
 
  end subroutine convex_down_ramp_mapping_apply_backward
 
end module ramp_mapping