topopt-user.f90

Go to the documentation of this file.

 
 
program topopt_user
  use neko, only: neko_init, neko_finalize
  use simulation_m, only: simulation_t
  use design, only: design_t, design_factory
  use problem, only: problem_t
  use optimizer, only: optimizer_t, optimizer_factory
 
  use json_module, only: json_file
  use json_utils, only: json_get
  use utils, only: neko_error
  use json_utils_ext, only: json_read_file
  use neko_top, only: neko_top_register_types
  use user, only: user_setup
  use continuation_scheduler, only: nekotop_continuation
 
  implicit none
 
  ! JSON related arguments
  integer :: argc
  character(len=256) :: parameter_file
  type(json_file) :: parameters, design_parameters
 
  type(simulation_t) :: sim
  class(design_t), allocatable :: des
  type(problem_t) :: prob
  class(optimizer_t), allocatable :: opt
 
  ! -------------------------------------------------------------------------- !
  ! Initialize the Neko environment
 
  call neko_init()
  call neko_top_register_types()
 
  ! -------------------------------------------------------------------------- !
  ! Read the parameters file as the first terminal argument
 
  argc = command_argument_count()
  if (argc .lt. 1) call neko_error('Missing parameter file')
  call get_command_argument(1, parameter_file)
 
  ! Read the parameters file
  parameters = json_read_file(trim(parameter_file))
  call json_get(parameters, 'optimization.design', design_parameters)
 
  ! -------------------------------------------------------------------------- !
  ! Initialization of the components
 
  ! initialize the global continuation_scheduler object (nekotop_continuation)
  call nekotop_continuation%init(parameters)
 
  ! initialize the user additions for the forward (through the neko interface)
  call user_setup(sim%neko_case%user)
 
  ! initialize the simulation
  call sim%init(parameters)
 
  ! initialize the design
  call design_factory(des, design_parameters, sim)
 
  ! initialize the problem
  call prob%init(parameters, des, sim)
 
  ! initialize the optimizer
  call optimizer_factory(opt, parameters, prob, des, sim)
 
  ! -------------------------------------------------------------------------- !
  ! Execute the optimization
 
  call opt%run(prob, des, sim)
 
  ! -------------------------------------------------------------------------- !
  ! Clean up the components
 
  call opt%free()
  call prob%free()
  call des%free()
  call sim%free()
  call nekotop_continuation%free()
 
  if (allocated(des)) deallocate(des)
  if (allocated(opt)) deallocate(opt)
 
  ! Finalize the Neko environment
  call neko_finalize()
 
end program topopt_user