viscous_dissipation_objective.f90

Go to the documentation of this file.

 
!
!
! I promise I'll write this document properly in the future...
!
! But the Borval Peterson (I think) paper had an objective function
! that had 2 terms, dissipation and this term they claimed represented
! out of plane stresses.
! I never really understood that extra term, I also don't think it
! applies to 3D cases, but everyone includes it anyway.
!
! It appears to me to be basically a heuristic penality that targets
! non-binary designs
!
! so let's call
!
! F = \int |\nabla u|^2  + K \int \chi \u^2
!
!      | dissipation |     |"Brinkman dissipation"|
!
! I say "Brinkman dissipation" because they said it came from lubrication
! theory...
! Anyway, we can change all this later (especially the names!)
 
! If the objective function \frac{\mu}{2} \int |\nabla u|^2,
! the corresponding adjoint forcing is \mu \int \nabla v \cdot \nabla u
!
! for the Brinkman dissipation, the adjoint forcing is \chi u
!
! This has always annoyed me...
! because now I see one objective and one constraint
!
module viscous_dissipation_objective
  use num_types, only: rp
  use field, only: field_t
  use field_math, only: field_col3, field_addcol3, field_cmult, field_add2s2, &
       field_copy
  use operators, only: grad
  use adjoint_fluid_pnpn, only: adjoint_fluid_pnpn_t
  use scratch_registry, only: neko_scratch_registry
  use adjoint_viscous_dissipation_source_term, only: &
       adjoint_viscous_dissipation_source_term_t
  use objective, only: objective_t
  use simulation_m, only: simulation_t
  use adjoint_fluid_scheme, only: adjoint_fluid_scheme_t
  use coefs, only: coef_t
  use registry, only: neko_registry
  use neko_config, only: neko_bcknd_device
  use math, only: glsc2, copy
  use device_math, only: device_copy, device_glsc2
  use design, only: design_t
  use brinkman_design, only: brinkman_design_t
  use point_zone, only: point_zone_t
  use mask_ops, only: mask_exterior_const, compute_masked_volume
  use math_ext, only: glsc2_mask
  use utils, only: neko_error
  use json_module, only: json_file
  use json_utils, only: json_get_or_default
  use continuation_scheduler, only: nekotop_continuation
  implicit none
  private
 
  type, public, extends(objective_t) :: viscous_dissipation_objective_t
     private
 
     type(field_t), pointer :: u => null()
     type(field_t), pointer :: v => null()
     type(field_t), pointer :: w => null()
     type(coef_t), pointer :: c_xh => null()
     type(field_t), pointer :: adjoint_u => null()
     type(field_t), pointer :: adjoint_v => null()
     type(field_t), pointer :: adjoint_w => null()
     real(kind=rp) :: volume
     real(kind=rp) :: viscosity
 
   contains
     procedure, public, pass(this) :: init_json_sim => &
          viscous_dissipation_init_json_sim
     procedure, public, pass(this) :: init_from_attributes => &
          viscous_dissipation_init_attributes
     procedure, public, pass(this) :: free => viscous_dissipation_free
     procedure, public, pass(this) :: update_value => &
          viscous_dissipation_update_value
     procedure, public, pass(this) :: update_sensitivity => &
          viscous_dissipation_update_sensitivity
 
  end type viscous_dissipation_objective_t
 
contains
 
  subroutine viscous_dissipation_init_json_sim(this, json, design, simulation)
    class(viscous_dissipation_objective_t), intent(inout) :: this
    type(json_file), intent(inout) :: json
    class(design_t), intent(in) :: design
    type(simulation_t), target, intent(inout) :: simulation
 
    character(len=:), allocatable :: name
    character(len=:), allocatable :: mask_name
    real(kind=rp) :: weight
 
    weight = 1.0_rp
    call nekotop_continuation%json_get_or_register(json, 'weight', &
         this%weight, weight)
    call json_get_or_default(json, "mask_name", mask_name, "")
    call json_get_or_default(json, "name", name, "Dissipation")
 
    call this%init_from_attributes(design, simulation, weight, name, mask_name)
  end subroutine viscous_dissipation_init_json_sim
 
  subroutine viscous_dissipation_init_attributes(this, design, simulation, &
       weight, name, mask_name)
    class(viscous_dissipation_objective_t), intent(inout) :: this
    class(design_t), intent(in) :: design
    type(simulation_t), target, intent(inout) :: simulation
    real(kind=rp), intent(in) :: weight
    character(len=*), intent(in) :: name
    character(len=*), intent(in) :: mask_name
    type(adjoint_viscous_dissipation_source_term_t) :: adjoint_forcing
 
    call this%init_base(name, design%size(), weight, mask_name)
 
    ! Save the simulation and design
    this%u => neko_registry%get_field('u')
    this%v => neko_registry%get_field('v')
    this%w => neko_registry%get_field('w')
    this%c_Xh => simulation%fluid%c_Xh
    this%adjoint_u => neko_registry%get_field('u_adj')
    this%adjoint_v => neko_registry%get_field('v_adj')
    this%adjoint_w => neko_registry%get_field('w_adj')
    this%viscosity = simulation%fluid%mu%x(1,1,1,1)
 
    ! compute the volume of the objective domain
    if (this%has_mask) then
       this%volume = compute_masked_volume(this%mask, this%c_Xh)
    else
       this%volume = this%c_Xh%volume
    end if
 
    ! you will need to init this!
    ! append a source term based on the viscous dissipation
    ! init the adjoint forcing term for the adjoint
    call adjoint_forcing%init_from_components( &
         simulation%adjoint_fluid%f_adj_x, &
         simulation%adjoint_fluid%f_adj_y, &
         simulation%adjoint_fluid%f_adj_z, &
         this%u, this%v, this%w, this%weight * this%viscosity, &
         this%mask, this%has_mask, &
         this%c_Xh, this%volume)
 
    ! append adjoint forcing term based on objective function
    select type (f => simulation%adjoint_fluid)
    type is (adjoint_fluid_pnpn_t)
       call f%source_term%add_source_term(adjoint_forcing)
    end select
 
  end subroutine viscous_dissipation_init_attributes
 
  subroutine viscous_dissipation_free(this)
    class(viscous_dissipation_objective_t), intent(inout) :: this
    call this%free_base()
 
    if (associated(this%u)) nullify(this%u)
    if (associated(this%v)) nullify(this%v)
    if (associated(this%w)) nullify(this%w)
    if (associated(this%c_Xh)) nullify(this%c_Xh)
 
    if (associated(this%adjoint_u)) nullify(this%adjoint_u)
    if (associated(this%adjoint_v)) nullify(this%adjoint_v)
    if (associated(this%adjoint_w)) nullify(this%adjoint_w)
 
  end subroutine viscous_dissipation_free
 
  subroutine viscous_dissipation_update_value(this, design)
    class(viscous_dissipation_objective_t), intent(inout) :: this
    class(design_t), intent(in) :: design
    type(field_t), pointer :: wo1, wo2, wo3, work
    type(field_t), pointer :: objective_field
    integer :: temp_indices(5)
    integer n
 
    call neko_scratch_registry%request_field(wo1, temp_indices(1), .false.)
    call neko_scratch_registry%request_field(wo2, temp_indices(2), .false.)
    call neko_scratch_registry%request_field(wo3, temp_indices(3), .false.)
    call neko_scratch_registry%request_field(objective_field, temp_indices(4), &
         .false.)
    call neko_scratch_registry%request_field(work, temp_indices(5), .false.)
 
    ! update_value the objective function.
    call grad(wo1%x, wo2%x, wo3%x, this%u%x, this%c_Xh)
    call field_col3(objective_field, wo1, wo1)
    call field_addcol3(objective_field, wo2, wo2)
    call field_addcol3(objective_field, wo3, wo3)
 
    call grad(wo1%x, wo2%x, wo3%x, this%v%x, this%c_Xh)
    call field_addcol3(objective_field, wo1, wo1)
    call field_addcol3(objective_field, wo2, wo2)
    call field_addcol3(objective_field, wo3, wo3)
 
    call grad(wo1%x, wo2%x, wo3%x, this%w%x, this%c_Xh)
    call field_addcol3(objective_field, wo1, wo1)
    call field_addcol3(objective_field, wo2, wo2)
    call field_addcol3(objective_field, wo3, wo3)
 
    ! integrate the field
    n = wo1%size()
    if (this%has_mask) then
       if (neko_bcknd_device .eq. 1) then
          ! note, this could be done more elagantly by writing
          ! device_glsc2_mask
          call field_copy(work, objective_field)
          call mask_exterior_const(work, this%mask, 0.0_rp)
          this%value = device_glsc2(work%x_d, this%c_xh%B_d, n)
       else
          this%value = glsc2_mask(objective_field%x, this%c_Xh%b, &
               n, this%mask%mask%get(), this%mask%size)
       end if
    else
       if (neko_bcknd_device .eq. 1) then
          this%value = device_glsc2(objective_field%x_d, &
               this%c_Xh%b_d, n)
       else
          this%value = glsc2(objective_field%x, this%c_Xh%b, n)
       end if
    end if
 
    this%value = this%value * 0.5_rp * this%viscosity / this%volume
 
    call neko_scratch_registry%relinquish_field(temp_indices)
 
  end subroutine viscous_dissipation_update_value
 
  subroutine viscous_dissipation_update_sensitivity(this, design)
    class(viscous_dissipation_objective_t), intent(inout) :: this
    class(design_t), intent(in) :: design
 
  end subroutine viscous_dissipation_update_sensitivity
 
end module viscous_dissipation_objective