optimizer_hdf5_io.f90

 
 
submodule(optimizer) optimizer_hdf5_io
  use hdf5
  use mpi_f08, only: mpi_info_null
  use comm, only: neko_comm
  use hdf5_session, only: hdf5_session_init, hdf5_session_finalize
 
contains
 
  ! -------------------------------------------------------------------------- !
  ! Checkpointing methods for the optimizer optimizer
 
  subroutine optimizer_save_checkpoint_hdf5(object, filename, overwrite)
    class(optimizer_t), intent(inout) :: object
    character(len=*), intent(in) :: filename
    logical, intent(in), optional :: overwrite
    logical :: overwrite_flag, file_exists
 
    ! HDF5 variables
    integer(hid_t) :: file_id, fapl_id, filespace, str_type
    integer(hid_t) :: grp_id, optimizer_grp_id, attr_id
    integer :: ierr, info
    integer(hsize_t) :: ddim(1)
    logical :: optimizer_exists
 
    overwrite_flag = .false.
    if (present(overwrite)) overwrite_flag = overwrite
 
    ! ------------------------------------------------------------------------ !
    ! Prepare the HDF5 file, settings for MPIO access and groups
 
    call hdf5_session_init()
    call h5pcreate_f(h5p_file_access_f, fapl_id, ierr)
    info = mpi_info_null%mpi_val
    call h5pset_fapl_mpio_f(fapl_id, neko_comm%mpi_val, info, ierr)
 
    ! Handle overwriting if the file exists
    file_exists = .false.
    inquire(file=trim(filename), exist=file_exists)
    if (.not. file_exists) then
       call h5fcreate_f(trim(filename), h5f_acc_trunc_f, file_id, ierr, &
            access_prp = fapl_id)
 
       ! Create the Optimizer/checkpoint group
       call h5gcreate_f(file_id, "Optimizer", optimizer_grp_id, ierr)
       call h5gcreate_f(optimizer_grp_id, "checkpoint", grp_id, ierr)
 
    else
       call h5fopen_f(trim(filename), h5f_acc_rdwr_f, file_id, ierr, fapl_id)
 
       ! Check for existing Optimizer group
       optimizer_exists = .false.
       call h5lexists_f(file_id, 'Optimizer', optimizer_exists, ierr)
 
       if (.not. optimizer_exists) then
          ! Create the Optimizer/checkpoint group
          call h5gcreate_f(file_id, "Optimizer", optimizer_grp_id, ierr)
          call h5gcreate_f(optimizer_grp_id, "checkpoint", grp_id, ierr)
       else
          ! Open the existing "Optimizer" group
          call h5gopen_f(file_id, 'Optimizer', optimizer_grp_id, ierr)
          call h5lexists_f(optimizer_grp_id, 'checkpoint', optimizer_exists, ierr)
 
          if (optimizer_exists .and. overwrite_flag) then
             call h5gunlink_f(optimizer_grp_id, "checkpoint", ierr)
             call h5gcreate_f(optimizer_grp_id, "checkpoint", grp_id, ierr)
          else
             call neko_error('optimizer: HDF5 file "' // trim(filename) // '" ' &
                  // 'already contains Optimizer group; ' &
                  // 'use overwrite option to replace')
          end if
       end if
    end if
    call h5gclose_f(optimizer_grp_id, ierr)
 
    ! ------------------------------------------------------------------------ !
    ! Write the optimizer optimizer checkpoint group
 
    ! Create the dataspace for attributes
    call h5screate_f(h5s_scalar_f, filespace, ierr)
 
    ! Save the optimizer type
    call h5tcopy_f(h5t_fortran_s1, str_type, ierr)
    call h5tset_strpad_f(str_type, h5t_str_spacepad_f, ierr)
 
    ddim(1) = len_trim(object%optimizer_type)
    call h5tset_size_f(str_type, ddim(1), ierr)
    call h5acreate_f(grp_id, 'type', str_type, filespace, attr_id, &
         ierr, h5p_default_f, h5p_default_f)
    call h5awrite_f(attr_id, str_type, object%optimizer_type, ddim, ierr)
    call h5aclose_f(attr_id, ierr)
    call h5tclose_f(str_type, ierr)
 
    ! Save the current iteration number
    ddim = 1
    call h5acreate_f(grp_id, 'iter', h5t_native_integer, filespace, attr_id, &
         ierr, h5p_default_f, h5p_default_f)
    call h5awrite_f(attr_id, h5t_native_integer, object%current_iteration, &
         ddim, ierr)
    call h5aclose_f(attr_id, ierr)
 
    ! ------------------------------------------------------------------------ !
    ! Close HDF5 objects
    call h5sclose_f(filespace, ierr)
    call h5gclose_f(grp_id, ierr)
    call h5fclose_f(file_id, ierr)
    call h5pclose_f(fapl_id, ierr)
 
    call hdf5_session_finalize()
 
  end subroutine optimizer_save_checkpoint_hdf5
 
  subroutine optimizer_load_checkpoint_hdf5(object, filename)
    class(optimizer_t), intent(inout) :: object
    character(len=*), intent(in) :: filename
 
    ! HDF5 variables
    character(len=64) :: type_name
    integer(hid_t) :: file_id, fapl_id, grp_id, attr_id, str_type
    integer :: ierr, info
    integer(hsize_t) :: ddim(1)
    character(len=*), parameter :: h5_group = 'Optimizer/checkpoint'
 
    ! Initialize reader variables
    type_name = ''
 
    ! ------------------------------------------------------------------------ !
    ! Open the HDF5 context and read identification parameters
 
    call hdf5_session_init()
 
    ! Prepare the HDF5 settings for MPIO access
    call h5pcreate_f(h5p_file_access_f, fapl_id, ierr)
    info = mpi_info_null%mpi_val
    call h5pset_fapl_mpio_f(fapl_id, neko_comm%mpi_val, info, ierr)
 
    ! Open the HDF5 file
    call h5fopen_f(trim(filename), h5f_acc_rdonly_f, file_id, ierr, &
         access_prp = fapl_id)
 
    ! Open the optimizer optimizer checkpoint group
    call h5gopen_f(file_id, trim(h5_group), grp_id, ierr)
 
    if (ierr .ne. 0) then
       call neko_error('optimizer: unable to open HDF5 file "' // &
            trim(filename) // '"')
    end if
 
    ! Read the optimizer type and verify
    ddim(1) = 1
    call h5aopen_f(grp_id, 'type', attr_id, ierr)
    call h5aget_type_f(attr_id, str_type, ierr)
    call h5aread_f(attr_id, str_type, type_name, ddim, ierr)
    call h5tclose_f(str_type, ierr)
    call h5aclose_f(attr_id, ierr)
 
    ! Verify that the type is optimizer
    if (trim(type_name) .ne. trim(object%optimizer_type)) then
       call neko_error("Incompatible optimizer type in checkpoint file")
    end if
 
    ! Read the current optimizer iteration
    ddim(1) = 1
    call h5aopen_f(grp_id, 'iter', attr_id, ierr)
    call h5aread_f(attr_id, h5t_native_integer, object%current_iteration, &
         ddim, ierr)
    call h5aclose_f(attr_id, ierr)
 
    if (object%current_iteration .lt. 0) then
       call neko_error("Incompatible optimizer iteration in checkpoint file")
    end if
 
    ! Read the current iteration
    call h5gclose_f(grp_id, ierr)
    call h5fclose_f(file_id, ierr)
    call h5pclose_f(fapl_id, ierr)
 
    call hdf5_session_finalize()
 
  end subroutine optimizer_load_checkpoint_hdf5
 
end submodule optimizer_hdf5_io