normal_vec_bcs.f90

Go to the documentation of this file.

 
module normal_vec_bcs
  use num_types, only : rp
  use neko_config, only : neko_bcknd_device
  use vector, only : vector_t
  use coefs, only : coef_t
  use bc, only : bc_t
  use utils, only : neko_error, nonlinear_index
  use json_module, only : json_file
  use, intrinsic :: iso_c_binding, only : c_ptr, c_null_ptr, c_associated
  use htable, only : htable_i4_t
  use device, only : device_map, device_memcpy, device_unmap, &
       host_to_device
  use time_state, only : time_state_t
  implicit none
  private
 
  type, public, extends(bc_t) :: normal_vec_bcs_t
     integer, allocatable :: unique_mask(:)
     type(c_ptr) :: unique_mask_d = c_null_ptr
     type(vector_t) :: nx, ny, nz, work
   contains
     procedure, pass(this) :: apply_scalar => normal_vec_bcs_apply_scalar
     procedure, pass(this) :: apply_scalar_dev => &
          normal_vec_bcs_apply_scalar_dev
     procedure, pass(this) :: apply_vector => normal_vec_bcs_apply_vector
     procedure, pass(this) :: apply_vector_dev => &
          normal_vec_bcs_apply_vector_dev
     procedure, pass(this) :: apply_n_dot => normal_vec_bcs_apply_n_dot
     procedure, pass(this) :: apply_n_cross => normal_vec_bcs_apply_n_cross
     procedure, pass(this) :: init => normal_vec_bcs_init
     procedure, pass(this) :: init_from_components => &
          normal_vec_bcs_init_from_components
     procedure, pass(this) :: free => normal_vec_bcs_free
     procedure, pass(this) :: finalize => normal_vec_bcs_finalize
  end type normal_vec_bcs_t
 
contains
 
  subroutine normal_vec_bcs_init(this, coef, json)
    class(normal_vec_bcs_t), intent(inout), target :: this
    type(coef_t), target, intent(in) :: coef
    type(json_file), intent(inout) ::json
 
    call this%init_from_components(coef)
  end subroutine normal_vec_bcs_init
 
  subroutine normal_vec_bcs_init_from_components(this, coef)
    class(normal_vec_bcs_t), intent(inout), target :: this
    type(coef_t), target, intent(in) :: coef
 
    call this%init_base(coef)
  end subroutine normal_vec_bcs_init_from_components
 
  subroutine normal_vec_bcs_apply_scalar(this, x, n, time, strong)
    class(normal_vec_bcs_t), intent(inout) :: this
    integer, intent(in) :: n
    real(kind=rp), intent(inout), dimension(n) :: x
    type(time_state_t), intent(in), optional :: time
    logical, intent(in), optional :: strong
  end subroutine normal_vec_bcs_apply_scalar
 
  subroutine normal_vec_bcs_apply_scalar_dev(this, x_d, time, strong, strm)
    class(normal_vec_bcs_t), intent(inout), target :: this
    type(c_ptr),intent(inout) :: x_d
    type(time_state_t), intent(in), optional :: time
    logical, intent(in), optional :: strong
    type(c_ptr), intent(inout) :: strm
 
  end subroutine normal_vec_bcs_apply_scalar_dev
 
  subroutine normal_vec_bcs_apply_vector_dev(this, x_d, y_d, z_d, time, &
       strong, strm)
    class(normal_vec_bcs_t), intent(inout), target :: this
    type(c_ptr), intent(inout) :: x_d
    type(c_ptr), intent(inout) :: y_d
    type(c_ptr), intent(inout) :: z_d
    type(time_state_t), intent(in), optional :: time
    logical, intent(in), optional :: strong
    type(c_ptr), intent(inout) :: strm
 
  end subroutine normal_vec_bcs_apply_vector_dev
 
  subroutine normal_vec_bcs_apply_vector(this, x, y, z, n, time, strong)
    class(normal_vec_bcs_t), intent(inout) :: this
    integer, intent(in) :: n
    real(kind=rp), intent(inout), dimension(n) :: x
    real(kind=rp), intent(inout), dimension(n) :: y
    real(kind=rp), intent(inout), dimension(n) :: z
    type(time_state_t), intent(in), optional :: time
    logical, intent(in), optional :: strong
  end subroutine normal_vec_bcs_apply_vector
 
  subroutine normal_vec_bcs_apply_n_dot(this, f, u, v, w, n, time)
    class(normal_vec_bcs_t), intent(in) :: this
    integer, intent(in) :: n
    real(kind=rp), intent(inout), dimension(n) :: f
    real(kind=rp), intent(inout), dimension(n) :: u
    real(kind=rp), intent(inout), dimension(n) :: v
    real(kind=rp), intent(inout), dimension(n) :: w
    type(time_state_t), intent(in), optional :: time
    integer :: i, m, k
 
    m = this%unique_mask(0)
 
    ! This should be implemented n dot u weighted by the 2D mass matrix, which
    ! I believe is the area, and it appears that n is weighted by the area.
    do i = 1, m
       k = this%unique_mask(i)
       f(k) = u(k) * this%nx%x(i) + v(k) * this%ny%x(i) + w(k) * this%nz%x(i)
    end do
 
  end subroutine normal_vec_bcs_apply_n_dot
 
  subroutine normal_vec_bcs_apply_n_cross(this, x, y, z, u, v, w, n, time)
    class(normal_vec_bcs_t), intent(in) :: this
    integer, intent(in) :: n
    real(kind=rp), intent(inout), dimension(n) :: x
    real(kind=rp), intent(inout), dimension(n) :: y
    real(kind=rp), intent(inout), dimension(n) :: z
    real(kind=rp), intent(inout), dimension(n) :: u
    real(kind=rp), intent(inout), dimension(n) :: v
    real(kind=rp), intent(inout), dimension(n) :: w
    type(time_state_t), intent(in), optional :: time
    integer :: i, m, k
 
    m = this%unique_mask(0)
 
    do i = 1, m
       k = this%unique_mask(i)
       x(k) = this%ny%x(i) * w(k) - this%nz%x(i) * v(k)
       y(k) = this%nz%x(i) * u(k) - this%nx%x(i) * w(k)
       z(k) = this%nx%x(i) * v(k) - this%ny%x(i) * u(k)
    end do
 
  end subroutine normal_vec_bcs_apply_n_cross
 
  subroutine normal_vec_bcs_free(this)
    class(normal_vec_bcs_t), target, intent(inout) :: this
 
    call this%free_base()
    if (allocated(this%unique_mask)) then
       if (c_associated(this%unique_mask_d)) then
          call device_unmap(this%unique_mask, this%unique_mask_d)
       end if
       deallocate(this%unique_mask)
    end if
 
    call this%nx%free()
    call this%ny%free()
    call this%nz%free()
    call this%work%free()
 
  end subroutine normal_vec_bcs_free
 
  subroutine normal_vec_bcs_finalize(this)
    class(normal_vec_bcs_t), target, intent(inout) :: this
    type(htable_i4_t) :: unique_point_idx
    integer :: htable_data, rcode, i, j, idx(4), facet
    real(kind=rp) :: area, normal(3)
 
    call this%finalize_base()
    ! This part is purely needed to ensure that contributions
    ! for all faces a point is on is properly summed up.
    ! If one simply uses the original mask, if a point is on a corner
    ! where both faces are on the boundary
    ! one will only get the contribution from one face, not both
    ! We solve this by adding up the normals of both faces for these points
    ! and storing this sum in this%nx, this%ny, this%nz.
    ! As both contrbutions are added already,
    ! we also ensure that we only visit each point once
    ! and create a new mask with only unique points (this%unique_mask).
    if (allocated(this%unique_mask)) then
       if (c_associated(this%unique_mask_d)) then
          call device_unmap(this%unique_mask, this%unique_mask_d)
       end if
       deallocate(this%unique_mask)
    end if
 
    call unique_point_idx%init(this%facet_node_msk(0), htable_data)
    j = 0
    do i = 1, this%facet_node_msk(0)
       if (unique_point_idx%get(this%facet_node_msk(i), htable_data) .ne. 0) then
          j = j + 1
          htable_data = j
          call unique_point_idx%set(this%facet_node_msk(i), j)
       end if
    end do
 
    ! Only allocate work vectors if size is non-zero
    if (unique_point_idx%num_entries() .gt. 0 ) then
       call this%nx%init(unique_point_idx%num_entries())
       call this%ny%init(unique_point_idx%num_entries())
       call this%nz%init(unique_point_idx%num_entries())
       call this%work%init(unique_point_idx%num_entries())
    end if
    allocate(this%unique_mask(0:unique_point_idx%num_entries()))
 
    this%unique_mask(0) = unique_point_idx%num_entries()
    do i = 1, this%unique_mask(0)
       this%unique_mask(i) = 0
    end do
 
 
    do i = 1, this%facet_node_msk(0)
       rcode = unique_point_idx%get(this%facet_node_msk(i), htable_data)
       if (rcode .ne. 0) call neko_error("Facet normal: htable get failed.")
       this%unique_mask(htable_data) = this%facet_node_msk(i)
       facet = this%facet(i)
 
       idx = nonlinear_index(this%facet_node_msk(i), this%Xh%lx, this%Xh%lx, &
            this%Xh%lx)
       normal = this%coef%get_normal(idx(1), idx(2), idx(3), idx(4), facet)
       area = this%coef%get_area(idx(1), idx(2), idx(3), idx(4), facet)
       normal = normal * area !Scale normal by area
       this%nx%x(htable_data) = this%nx%x(htable_data) + normal(1)
       this%ny%x(htable_data) = this%ny%x(htable_data) + normal(2)
       this%nz%x(htable_data) = this%nz%x(htable_data) + normal(3)
    end do
 
    if (neko_bcknd_device .eq. 1 .and. &
         (unique_point_idx%num_entries() .gt. 0 )) then
       call device_map(this%unique_mask, this%unique_mask_d, &
            size(this%unique_mask))
       call device_memcpy(this%unique_mask, this%unique_mask_d, &
            size(this%unique_mask), host_to_device, sync = .true.)
       call device_memcpy(this%nx%x, this%nx%x_d, &
            this%nx%size(), host_to_device, sync = .true.)
       call device_memcpy(this%ny%x, this%ny%x_d, &
            this%ny%size(), host_to_device, sync = .true.)
       call device_memcpy(this%nz%x, this%nz%x_d, &
            this%nz%size(), host_to_device, sync = .true.)
    end if
 
    call unique_point_idx%free()
 
  end subroutine normal_vec_bcs_finalize
 
end module normal_vec_bcs