constraint_factory.f90

 
 
submodule(constraint) constraint_factory_mod
  use json_utils, only: json_get
  use utils, only: neko_type_error
 
  ! Import the constraint function types
  use volume_constraint, only: volume_constraint_t
 
  implicit none
 
  character(len=25), parameter :: KNOWN_TYPES(1) = [ character(len=25) :: &
       "volume"]
 
contains
 
  ! -------------------------------------------------------------------------- !
  ! Factory function
 
  module subroutine constraint_factory(object, json, design, simulation)
    class(constraint_t), allocatable, intent(inout) :: object
    type(json_file), intent(inout) :: json
    class(design_t), intent(in) :: design
    type(simulation_t), target, optional, intent(inout) :: simulation
    character(len=:), allocatable :: type
 
    if (allocated(object)) then
       call object%free()
       deallocate(object)
    end if
 
    call json_get(json, "type", type)
    select case (trim(type))
    case ("volume")
       allocate(volume_constraint_t::object)
    case default
       call neko_type_error("Constraint", type, KNOWN_TYPES)
    end select
 
    call object%init(json, design, simulation)
  end subroutine constraint_factory
 
end submodule constraint_factory_mod