adjoint_source_term.f90

Go to the documentation of this file.

 
!
module adjoint_source_term
  use user_source_term, only: user_source_term_t
  use source_term, only: source_term_t
  use source_term_handler, only: source_term_handler_t
  use field, only: field_t
  use field_list, only: field_list_t
  use coefs, only: coef_t
  use user_intf, only: user_t
  implicit none
  private
 
  type, public, extends(source_term_handler_t) :: adjoint_source_term_t
 
   contains
     procedure, pass(this) :: init => adjoint_source_term_init
     procedure, nopass :: init_user_source => adjoint_init_user_source
 
  end type adjoint_source_term_t
 
contains
 
  subroutine adjoint_source_term_init(this, f_x, f_y, f_z, coef, user, &
       scheme_name)
    class(adjoint_source_term_t), intent(inout) :: this
    type(field_t), pointer, intent(in) :: f_x, f_y, f_z
    type(coef_t), target, intent(in) :: coef
    type(user_t), target, intent(in) :: user
    character(len=*), intent(in) :: scheme_name
 
    type(field_list_t) :: rhs_fields
 
    ! We package the fields for the source term to operate on in a field list.
    call rhs_fields%init(3)
    call rhs_fields%assign(1, f_x)
    call rhs_fields%assign(2, f_y)
    call rhs_fields%assign(3, f_z)
 
    ! is this ever used??
    call this%init_base(rhs_fields, coef, user, scheme_name)
  end subroutine adjoint_source_term_init
 
  subroutine adjoint_init_user_source(source_term, rhs_fields, coef, user, &
       scheme_name)
    class(source_term_t), allocatable, intent(inout) :: source_term
    type(field_list_t) :: rhs_fields
    type(coef_t), intent(in) :: coef
    type(user_t), intent(in) :: user
    character(len=*), intent(in) :: scheme_name
 
    allocate(user_source_term_t::source_term)
 
    select type (source_term)
    type is (user_source_term_t)
       call source_term%init_from_components(rhs_fields, coef, &
            user%source_term, scheme_name)
    end select
  end subroutine adjoint_init_user_source
 
end module adjoint_source_term