ext_cyl.f90

Go to the documentation of this file.

module user
  use neko
  use ieee_arithmetic, only: ieee_is_nan
 
  implicit none
 
contains
 
  ! Register user defined functions (see user_intf.f90)
  subroutine user_setup(usr)
    type(user_t), intent(inout) :: usr
 
    usr%fluid_user_ic => user_ic
 
  end subroutine user_setup
 
  ! User defined initial condition
  subroutine user_ic(u, v, w, p, params)
    type(field_t), intent(inout) :: u
    type(field_t), intent(inout) :: v
    type(field_t), intent(inout) :: w
    type(field_t), intent(inout) :: p
    type(json_file), intent(inout) :: params
    integer :: iel, ix, iy, iz
    real(kind=rp) :: fcoeff(3), xl(2)
 
 
 
    do iel = 1, u%msh%nelv
       do iz = 1, u%Xh%lz
          do iy = 1, u%Xh%ly
             do ix = 1, u%Xh%lx
                xl(1) = u%dof%x(ix, iy, iz, iel)
                xl(2) = u%dof%y(ix, iy, iz, iel)
                fcoeff(1) = 3.0e4_rp
                fcoeff(2) = -1.5e3_rp
                fcoeff(3) = 0.5e5_rp
                u%x(ix, iy, iz, iel) = math_ran_dst(ix, iy, iz, iel, xl, &
                     fcoeff) * 1.0e-08_rp
                fcoeff(1) = 2.3e4_rp
                fcoeff(2) = 2.3e3_rp
                fcoeff(3) = -2.0e5_rp
                v%x(ix, iy, iz, iel) = math_ran_dst(ix, iy, iz, iel, xl, &
                     fcoeff) * 1.0e-08_rp
                w%x(ix, iy, iz, iel) = 0.0_rp
             end do
          end do
       end do
    end do
 
    call device_memcpy(u%x, u%x_d, u%size(), host_to_device, .true.)
    call device_memcpy(v%x, v%x_d, v%size(), host_to_device, .true.)
    call device_memcpy(w%x, w%x_d, w%size(), host_to_device, .true.)
 
  end subroutine user_ic
 
 
 
  !=======================================================================
  real function math_ran_dst(ix, iy, iz, ieg, xl, fcoeff)
    implicit none
 
 
    ! argument list
    integer ix, iy, iz, ieg
    real(kind=rp) :: fcoeff(3), xl(2)
!-----------------------------------------------------------------------
    math_ran_dst = fcoeff(1)*(ieg+xl(1)*sin(xl(2))) + &
         fcoeff(2)*ix*iy + fcoeff(3)*ix
    math_ran_dst = 1.0e3_rp * sin(math_ran_dst)
    math_ran_dst = 1.0e3_rp * sin(math_ran_dst)
    math_ran_dst = cos(math_ran_dst)
 
    return
  end function math_ran_dst
 
end module user