adjoint_lube_source_term.f90

Go to the documentation of this file.

 
!
!
!
! I know this is a stupid naming convention...
! The `lube` aspect came from a paper that attributed this term to out of plane
! stresses based on lubrication theory.
!
! I preffer to think of it as a constraint that penalizes non-binary designs
!
! The term is $K \int_\Omega \frac{1}{2}\chi|\mathbf{u}|^2$
!
! the corresponding adjoint forcing is $K \chi \mathbf{u}$
module adjoint_lube_source_term
  use num_types, only: rp
  use field_list, only: field_list_t
  use json_module, only: json_file
  use source_term, only: source_term_t
  use coefs, only: coef_t
  use interpolation, only: interpolator_t
  use space, only: space_t, gl
  use field, only: field_t
  use time_state, only: time_state_t
  use design, only: design_t
  use brinkman_design, only: brinkman_design_t
  use field_math, only: field_addcol3, field_copy, field_cmult, field_add2, &
       field_col3
  use mask_ops, only: mask_exterior_const
  use point_zone, only: point_zone_t
  use utils, only: neko_error
  use registry, only : neko_registry
  use scratch_registry, only: neko_scratch_registry, scratch_registry_t
  use neko_config, only: neko_bcknd_device
  use math, only: col2, invcol2
  use device_math, only: device_col2, device_invcol2
  implicit none
  private
  public :: adjoint_lube_source_term_allocate
 
  ! $K \int_\Omega \frac{1}{2}\chi|\mathbf{u}|^2$.
  type, public, extends(source_term_t) :: adjoint_lube_source_term_t
 
     type(field_t), pointer :: u => null()
     type(field_t), pointer :: v => null()
     type(field_t), pointer :: w => null()
     type(field_t), pointer :: chi => null()
     real(kind=rp) :: k
     class(point_zone_t), pointer :: mask => null()
     logical :: if_mask
     logical :: dealias
     type(space_t), pointer :: xh_gll
     type(space_t), pointer :: xh_gl
     type(coef_t), pointer :: c_xh_gl
     type(interpolator_t), pointer :: gll_to_gl
     type(scratch_registry_t), pointer :: scratch_gl
     real(kind=rp) :: volume
 
   contains
     procedure, pass(this) :: init => adjoint_lube_source_term_init_from_json
     procedure, pass(this) :: init_from_components => &
          adjoint_lube_source_term_init_from_components
     procedure, pass(this) :: free => adjoint_lube_source_term_free
     procedure, pass(this) :: compute_ => adjoint_lube_source_term_compute
  end type adjoint_lube_source_term_t
 
contains
 
  subroutine adjoint_lube_source_term_allocate(obj)
    class(source_term_t), allocatable, intent(inout) :: obj
    allocate(adjoint_lube_source_term_t::obj)
  end subroutine adjoint_lube_source_term_allocate
 
  subroutine adjoint_lube_source_term_init_from_json(this, json, fields, coef, &
       variable_name)
    class(adjoint_lube_source_term_t), intent(inout) :: this
    type(json_file), intent(inout) :: json
    type(field_list_t), intent(in), target :: fields
    type(coef_t), intent(in), target :: coef
    character(len=*), intent(in) :: variable_name
    ! real(kind=rp), allocatable :: values(:)
    ! real(kind=rp) :: start_time, end_time
 
 
    ! we shouldn't be initializing this from JSON
    ! maybe throw an error?
 
 
  end subroutine adjoint_lube_source_term_init_from_json
 
  subroutine adjoint_lube_source_term_init_from_components(this, &
       f_x, f_y, f_z, design, K, &
       u, v, w, &
       mask, if_mask, &
       coef, c_Xh_GL, GLL_to_GL, dealias, volume, scratch_GL)
    class(adjoint_lube_source_term_t), intent(inout) :: this
    type(field_t), pointer, intent(in) :: f_x, f_y, f_z
    class(design_t), intent(in), target :: design
    real(kind=rp), intent(in) :: k
    type(field_t), intent(in), target :: u, v, w
    class(point_zone_t), intent(in), target :: mask
    logical :: if_mask
    type(coef_t), intent(in) :: coef
    type(coef_t), intent(in), target :: c_xh_gl
    type(interpolator_t), intent(in), target :: gll_to_gl
    logical, intent(in) :: dealias
    real(kind=rp), intent(in) :: volume
    type(scratch_registry_t), intent(in), target :: scratch_gl
    real(kind=rp) :: start_time
    real(kind=rp) :: end_time
    type(field_list_t) :: fields
 
    ! I wish you didn't need a start time and end time...
    ! but I'm just going to set a super big number...
    start_time = 0.0_rp
    end_time = 100000000.0_rp
 
    call this%free()
 
    ! this is copying the fluid source term init
    ! We package the fields for the source term to operate on in a field list.
    call fields%init(3)
    call fields%assign(1, f_x)
    call fields%assign(2, f_y)
    call fields%assign(3, f_z)
 
    call this%init_base(fields, coef, start_time, end_time)
 
    ! point everything in the correct places
    this%c_Xh_GL => c_xh_gl
    this%Xh_GL => this%c_Xh_GL%Xh
    this%Xh_GLL => this%coef%Xh
    this%GLL_to_GL => gll_to_gl
    this%dealias = dealias
    this%scratch_GL => scratch_gl
    this%u => u
    this%v => v
    this%w => w
 
    this%volume = volume
 
    select type (design)
    type is (brinkman_design_t)
       this%chi => neko_registry%get_field("brinkman_amplitude")
    class default
       call neko_error('Unknown design type')
    end select
 
    this%K = k
    this%if_mask = if_mask
    if (this%if_mask) then
       this%mask => mask
    end if
 
  end subroutine adjoint_lube_source_term_init_from_components
 
  subroutine adjoint_lube_source_term_free(this)
    class(adjoint_lube_source_term_t), intent(inout) :: this
 
    call this%free_base()
    nullify(this%u)
    nullify(this%v)
    nullify(this%w)
    nullify(this%c_Xh_GL)
    nullify(this%Xh_GL)
    nullify(this%Xh_GLL)
    nullify(this%GLL_to_GL)
    nullify(this%mask)
    nullify(this%scratch_GL)
 
  end subroutine adjoint_lube_source_term_free
 
  subroutine adjoint_lube_source_term_compute(this, time)
    class(adjoint_lube_source_term_t), intent(inout) :: this
    type(time_state_t), intent(in) :: time
    type(field_t), pointer :: fu, fv, fw
    type(field_t), pointer :: work
    integer :: temp_indices(1)
    type(field_t), pointer :: accumulate, fld_gl, chi_gl
    integer :: temp_indices_gl(3)
    integer :: n_gl, nel
 
    fu => this%fields%get_by_index(1)
    fv => this%fields%get_by_index(2)
    fw => this%fields%get_by_index(3)
 
    ! BE SO CAREFUL HERE
    ! It make look the same as the Brinkman term, but it's assumed that
    ! this source term acts on the adjoint, and the u,v,w here come from
    ! the primal
    call neko_scratch_registry%request_field(work, temp_indices(1), .false.)
    call field_copy(work, this%chi)
 
    ! scale by K and volume
    call field_cmult(work, this%K / this%volume)
 
    ! mask
    if (this%if_mask) then
       call mask_exterior_const(work, this%mask, 0.0_rp)
    end if
 
    if (this%dealias) then
       nel = this%coef%msh%nelv
       n_gl = nel * this%Xh_GL%lxyz
       call this%scratch_GL%request_field(accumulate, temp_indices_gl(1), &
            .false.)
       call this%scratch_GL%request_field(fld_gl, temp_indices_gl(2), .false.)
       call this%scratch_GL%request_field(chi_gl, temp_indices_gl(3), .false.)
 
       call this%GLL_to_GL%map(chi_gl%x, work%x, nel, this%Xh_GL)
 
       ! u
       call this%GLL_to_GL%map(fld_gl%x, this%u%x, nel, this%Xh_GL)
       call field_col3(accumulate, chi_gl, fld_gl)
       if (neko_bcknd_device .eq. 1) then
          call device_col2(accumulate%x_d, this%c_Xh_GL%B_d, n_gl)
          call this%GLL_to_GL%map(work%x, accumulate%x, nel, this%Xh_GLL)
          call device_invcol2(work%x_d, this%coef%B_d, work%size())
       else
          call col2(accumulate%x, this%c_Xh_GL%B, n_gl)
          call this%GLL_to_GL%map(work%x, accumulate%x, nel, this%Xh_GLL)
          call invcol2(work%x, this%coef%B, work%size())
       end if
       call field_add2(fu, work)
 
       ! v
       call this%GLL_to_GL%map(fld_gl%x, this%v%x, nel, this%Xh_GL)
       call field_col3(accumulate, chi_gl, fld_gl)
       if (neko_bcknd_device .eq. 1) then
          call device_col2(accumulate%x_d, this%c_Xh_GL%B_d, n_gl)
          call this%GLL_to_GL%map(work%x, accumulate%x, nel, this%Xh_GLL)
          call device_invcol2(work%x_d, this%coef%B_d, work%size())
       else
          call col2(accumulate%x, this%c_Xh_GL%B, n_gl)
          call this%GLL_to_GL%map(work%x, accumulate%x, nel, this%Xh_GLL)
          call invcol2(work%x, this%coef%B, work%size())
       end if
       call field_add2(fv, work)
 
       ! w
       call this%GLL_to_GL%map(fld_gl%x, this%w%x, nel, this%Xh_GL)
       call field_col3(accumulate, chi_gl, fld_gl)
       if (neko_bcknd_device .eq. 1) then
          call device_col2(accumulate%x_d, this%c_Xh_GL%B_d, n_gl)
          call this%GLL_to_GL%map(work%x, accumulate%x, nel, this%Xh_GLL)
          call device_invcol2(work%x_d, this%coef%B_d, work%size())
       else
          call col2(accumulate%x, this%c_Xh_GL%B, n_gl)
          call this%GLL_to_GL%map(work%x, accumulate%x, nel, this%Xh_GLL)
          call invcol2(work%x, this%coef%B, work%size())
       end if
       call field_add2(fw, work)
 
       call this%scratch_GL%relinquish_field(temp_indices_gl)
 
    else
       ! multiple and add the RHS
       call field_addcol3(fu, this%u, work)
       call field_addcol3(fv, this%v, work)
       call field_addcol3(fw, this%w, work)
 
    end if
 
    call neko_scratch_registry%relinquish_field(temp_indices)
 
  end subroutine adjoint_lube_source_term_compute
 
end module adjoint_lube_source_term