adjoint_minimum_dissipation_source_term.f90

Go to the documentation of this file.

 
!
!
!
! If the objective function $\int |\nabla u|^2$,
! the corresponding adjoint forcing is $ \int \nabla v \cdot \nabla u $ in weak
! form.
module adjoint_minimum_dissipation_source_term
  use num_types, only: rp
  use field_list, only: field_list_t
  use json_module, only: json_file
  use json_utils, only: json_get, json_get_or_default
  use source_term, only: source_term_t
  use coefs, only: coef_t
  use neko_config, only: neko_bcknd_device
  use utils, only: neko_error
  use field, only: field_t
  use field_math, only: field_subcol3, field_add2, field_add2s2, field_rzero
  use json_module, only: json_file
  use time_state, only: time_state_t
  use steady_simcomp, only: steady_simcomp_t
  use simcomp_executor, only: neko_simcomps
  use user_source_term, only: user_source_term_t
  use num_types, only: rp
  use field, only: field_t
  use registry, only: neko_registry
  use math, only: rzero, copy, chsign, cfill, invcol2
  use device_math, only: device_copy, device_cmult, device_cfill, device_invcol2
  use neko_config, only: neko_bcknd_device
  use scratch_registry, only: neko_scratch_registry
  use mask_ops, only: mask_exterior_const
  use point_zone, only: point_zone_t
  use ax_product, only : ax_t, ax_helm_factory
 
  implicit none
  private
  public :: adjoint_minimum_dissipation_source_term_allocate
 
  ! $\int \nabla v \cdot \nabla u $
  type, public, extends(source_term_t) :: &
       adjoint_minimum_dissipation_source_term_t
     type(field_t), pointer :: u => null()
     type(field_t), pointer :: v => null()
     type(field_t), pointer :: w => null()
     real(kind=rp) :: obj_scale
     class(point_zone_t), pointer :: mask => null()
     logical :: if_mask
     class(ax_t), allocatable :: ax
     real(kind=rp) :: volume
 
   contains
     procedure, pass(this) :: init => &
          adjoint_minimum_dissipation_source_term_init_from_json
     procedure, pass(this) :: init_from_components => &
          adjoint_minimum_dissipation_source_term_init_from_components
     procedure, pass(this) :: free => &
          adjoint_minimum_dissipation_source_term_free
     procedure, pass(this) :: compute_ => &
          adjoint_minimum_dissipation_source_term_compute
  end type adjoint_minimum_dissipation_source_term_t
 
contains
 
  subroutine adjoint_minimum_dissipation_source_term_allocate(obj)
    class(source_term_t), allocatable, intent(inout) :: obj
    allocate(adjoint_minimum_dissipation_source_term_t::obj)
  end subroutine adjoint_minimum_dissipation_source_term_allocate
 
  subroutine adjoint_minimum_dissipation_source_term_init_from_json(this, &
       json, fields, coef, variable_name)
    class(adjoint_minimum_dissipation_source_term_t), intent(inout) :: this
    type(json_file), intent(inout) :: json
    type(field_list_t), intent(in), target :: fields
    type(coef_t), intent(in), target :: coef
    character(len=*), intent(in) :: variable_name
 
    ! we shouldn't be initializing this from JSON
    ! maybe throw an error?
 
 
  end subroutine adjoint_minimum_dissipation_source_term_init_from_json
 
  subroutine adjoint_minimum_dissipation_source_term_init_from_components(this,&
       f_x, f_y, f_z, &
       u, v, w, obj_scale, &
       mask, if_mask, &
       coef, volume)
    class(adjoint_minimum_dissipation_source_term_t), intent(inout) :: this
    type(field_t), pointer, intent(in) :: f_x, f_y, f_z
    type(field_list_t) :: fields
    type(coef_t) :: coef
    real(kind=rp) :: start_time
    real(kind=rp) :: end_time
    real(kind=rp) :: obj_scale
    type(field_t), intent(in), target :: u, v, w
    class(point_zone_t), intent(in), target :: mask
    real(kind=rp), intent(in) :: volume
    logical :: if_mask
 
    ! I wish you didn't need a start time and end time...
    ! but I'm just going to set a super big number...
    start_time = 0.0_rp
    end_time = 100000000.0_rp
 
    call this%free()
 
    ! this is copying the fluid source term init
    ! We package the fields for the source term to operate on in a field list.
    call fields%init(3)
    call fields%assign(1, f_x)
    call fields%assign(2, f_y)
    call fields%assign(3, f_z)
 
    call this%init_base(fields, coef, start_time, end_time)
 
    ! point everything in the correct places
    this%u => u
    this%v => v
    this%w => w
 
    this%obj_scale = obj_scale
    this%volume = volume
 
    this%if_mask = if_mask
    if (this%if_mask) then
       this%mask => mask
    end if
 
    ! Initialize the ax_helm object
    call ax_helm_factory(this%Ax, full_formulation = .false.)
 
  end subroutine adjoint_minimum_dissipation_source_term_init_from_components
 
  subroutine adjoint_minimum_dissipation_source_term_free(this)
    class(adjoint_minimum_dissipation_source_term_t), intent(inout) :: this
 
    call this%free_base()
    nullify(this%u)
    nullify(this%v)
    nullify(this%w)
    nullify(this%mask)
    if (allocated(this%Ax)) then
       deallocate(this%Ax)
    end if
 
  end subroutine adjoint_minimum_dissipation_source_term_free
 
  subroutine adjoint_minimum_dissipation_source_term_compute(this, time)
    class(adjoint_minimum_dissipation_source_term_t), intent(inout) :: this
    type(time_state_t), intent(in) :: time
    type(field_t), pointer :: u, v, w
    type(field_t), pointer :: fu, fv, fw
    type(field_t), pointer :: work
    integer :: temp_indices(1)
    integer n
 
    fu => this%fields%get_by_index(1)
    fv => this%fields%get_by_index(2)
    fw => this%fields%get_by_index(3)
 
    n = fu%size()
 
    u => this%u
    v => this%v
    w => this%w
 
    call neko_scratch_registry%request_field(work, temp_indices(1), .false.)
 
    associate(coef => this%coef)
 
      ! Note that axhelm computes h1 * lap u + h2 * u
      ! we set h1 = 1 and h2 = 0 to compute the weak laplacian.
      if (neko_bcknd_device .eq. 1) then
         call device_cfill(coef%h1_d, 1.0_rp, n)
         call device_cfill(coef%h2_d, 0.0_rp, n)
      else
         call cfill(coef%h1, 1.0_rp, n)
         call cfill(coef%h2, 0.0_rp, n)
      end if
      coef%ifh2 = .false.
 
      ! ------------------------------------------------------------------------
      ! u
 
      call this%Ax%compute(work%x, u%x, coef, coef%msh, coef%xh)
 
      ! pre-divide out the mass matrix to counteract it's multiplication
      if (neko_bcknd_device .eq. 1) then
         call device_invcol2(work%x_d, coef%B_d, work%size())
      else
         call invcol2(work%x, coef%B, work%size())
      end if
 
      ! mask
      if (this%if_mask) then
         call mask_exterior_const(work, this%mask, 0.0_rp)
      end if
 
      ! add to RHS
      call field_add2s2(fu, work, this%obj_scale / this%volume)
 
      ! ------------------------------------------------------------------------
      ! v
 
      call this%Ax%compute(work%x, v%x, coef, coef%msh, coef%xh)
 
      ! pre-divide out the mass matrix to counteract it's multiplication
      if (neko_bcknd_device .eq. 1) then
         call device_invcol2(work%x_d, coef%B_d, work%size())
      else
         call invcol2(work%x, coef%B, work%size())
      end if
 
      ! mask
      if (this%if_mask) then
         call mask_exterior_const(work, this%mask, 0.0_rp)
      end if
 
      ! add to RHS
      call field_add2s2(fv, work, this%obj_scale / this%volume)
 
      ! ------------------------------------------------------------------------
      ! w
 
      call this%Ax%compute(work%x, w%x, coef, coef%msh, coef%xh)
 
      ! pre-divide out the mass matrix to counteract it's multiplication
      if (neko_bcknd_device .eq. 1) then
         call device_invcol2(work%x_d, coef%B_d, work%size())
      else
         call invcol2(work%x, coef%B, work%size())
      end if
 
      ! mask
      if (this%if_mask) then
         call mask_exterior_const(work, this%mask, 0.0_rp)
      end if
 
      ! add to RHS
      call field_add2s2(fw, work, this%obj_scale / this%volume)
 
      call neko_scratch_registry%relinquish_field(temp_indices)
 
    end associate
 
  end subroutine adjoint_minimum_dissipation_source_term_compute
 
end module adjoint_minimum_dissipation_source_term