simple_brinkman_source_term.f90

Go to the documentation of this file.

 
!
! a term in the form $\chi \mathbf{u}$
module simple_brinkman_source_term
  use num_types, only: rp
  use field_list, only: field_list_t
  use json_module, only: json_file
  use json_utils, only: json_get, json_get_or_default
  use source_term, only: source_term_t
  use coefs, only: coef_t
  use neko_config, only: neko_bcknd_device
  use time_state, only: time_state_t
  use utils, only: neko_error
  use field, only: field_t
  use field_math, only: field_subcol3, field_sub2, field_col3
  use interpolation, only: interpolator_t
  use space, only: space_t, gl
  use math, only: col2, invcol2
  use device_math, only: device_col2, device_invcol2
  use scratch_registry, only: neko_scratch_registry, scratch_registry_t
  implicit none
  private
  public :: simple_brinkman_source_term_allocate
 
  ! We have a source term of the form $\chi \mathbf{u}$
  type, public, extends(source_term_t) :: simple_brinkman_source_term_t
     type(field_t), pointer :: chi => null()
     type(field_t), pointer :: u => null()
     type(field_t), pointer :: v => null()
     type(field_t), pointer :: w => null()
     ! --- for over-integration
     type(space_t), pointer :: xh_gll
     type(space_t), pointer :: xh_gl
     type(coef_t), pointer :: c_xh_gl
     type(interpolator_t), pointer :: gll_to_gl
     logical :: dealias
     type(scratch_registry_t), pointer :: scratch_gl
 
   contains
     procedure, pass(this) :: init => &
          simple_brinkman_source_term_init_from_json
     procedure, pass(this) :: init_from_components => &
          simple_brinkman_source_term_init_from_components
     procedure, pass(this) :: free => simple_brinkman_source_term_free
     procedure, pass(this) :: compute_ => simple_brinkman_source_term_compute
  end type simple_brinkman_source_term_t
 
contains
 
  subroutine simple_brinkman_source_term_allocate(obj)
    class(source_term_t), allocatable, intent(inout) :: obj
    allocate(simple_brinkman_source_term_t::obj)
  end subroutine simple_brinkman_source_term_allocate
 
  subroutine simple_brinkman_source_term_init_from_json(this, json, fields, &
       coef, variable_name)
    class(simple_brinkman_source_term_t), intent(inout) :: this
    type(json_file), intent(inout) :: json
    type(field_list_t), intent(in), target :: fields
    type(coef_t), intent(in), target :: coef
    character(len=*), intent(in) :: variable_name
 
 
    ! we shouldn't be initializing this from JSON
    ! maybe throw an error?
 
 
  end subroutine simple_brinkman_source_term_init_from_json
 
  subroutine simple_brinkman_source_term_init_from_components(this, &
       f_x, f_y, f_z, chi, u, v, w, coef, c_Xh_GL, GLL_to_GL, dealias, &
       scratch_GL)
    class(simple_brinkman_source_term_t), intent(inout) :: this
    type(field_t), pointer, intent(in) :: f_x, f_y, f_z
    type(field_list_t) :: fields
    type(coef_t), intent(in) :: coef
    type(coef_t), intent(in), target :: c_xh_gl
    type(interpolator_t), intent(in), target :: gll_to_gl
    logical, intent(in) :: dealias
    real(kind=rp) :: start_time
    real(kind=rp) :: end_time
    type(field_t), intent(in), target :: u, v, w
    type(field_t), intent(in), target :: chi
    type(scratch_registry_t), intent(in), target :: scratch_gl
 
    ! I wish you didn't need a start time and end time...
    ! but I'm just going to set a super big number...
    start_time = 0.0_rp
    end_time = 100000000.0_rp
 
    call this%free()
 
    ! this is copying the fluid source term init
    ! We package the fields for the source term to operate on in a field list.
    call fields%init(3)
    call fields%assign(1, f_x)
    call fields%assign(2, f_y)
    call fields%assign(3, f_z)
 
    call this%init_base(fields, coef, start_time, end_time)
 
    ! point everything in the correct places
    this%u => u
    this%v => v
    this%w => w
    ! and get chi out of the design
    this%chi => chi
    ! for over integration
    this%dealias = dealias
    this%c_Xh_GL => c_xh_gl
    this%Xh_GL => this%c_Xh_GL%Xh
    this%Xh_GLL => this%coef%Xh
    this%GLL_to_GL => gll_to_gl
    this%scratch_GL => scratch_gl
 
  end subroutine simple_brinkman_source_term_init_from_components
 
  subroutine simple_brinkman_source_term_free(this)
    class(simple_brinkman_source_term_t), intent(inout) :: this
 
    call this%free_base()
    nullify(this%u)
    nullify(this%v)
    nullify(this%w)
    nullify(this%chi)
    nullify(this%c_Xh_GL)
    nullify(this%Xh_GL)
    nullify(this%Xh_GLL)
    nullify(this%GLL_to_GL)
    nullify(this%scratch_GL)
 
  end subroutine simple_brinkman_source_term_free
 
  subroutine simple_brinkman_source_term_compute(this, time)
    class(simple_brinkman_source_term_t), intent(inout) :: this
    type(time_state_t), intent(in) :: time
    type(field_t), pointer :: fu, fv, fw
    type(field_t), pointer :: work
    type(field_t), pointer :: accumulate, fld_gl, chi_gl
    integer :: temp_indices(1)
    integer :: temp_indices_gl(3)
    integer :: n_gl, nel
 
    fu => this%fields%get_by_index(1)
    fv => this%fields%get_by_index(2)
    fw => this%fields%get_by_index(3)
 
    call neko_scratch_registry%request_field(work, temp_indices(1), .false.)
 
    if (this%dealias) then
       nel = this%coef%msh%nelv
       n_gl = nel * this%Xh_GL%lxyz
       call this%scratch_GL%request_field(accumulate, &
            temp_indices_gl(1), .false.)
       call this%scratch_GL%request_field(fld_gl, &
            temp_indices_gl(2), .false.)
       call this%scratch_GL%request_field(chi_gl, &
            temp_indices_gl(3), .false.)
 
       call this%GLL_to_GL%map(chi_gl%x, this%chi%x, nel, this%Xh_GL)
 
       ! u
       call this%GLL_to_GL%map(fld_gl%x, this%u%x, nel, this%Xh_GL)
       call field_col3(accumulate, chi_gl, fld_gl)
       ! Evaluate term on GL and preempt the GLL premultiplication
       if (neko_bcknd_device .eq. 1) then
          call device_col2(accumulate%x_d, this%c_Xh_GL%B_d, n_gl)
          call this%GLL_to_GL%map(work%x, accumulate%x, nel, this%Xh_GLL)
          call device_invcol2(work%x_d, this%coef%B_d, work%size())
       else
          call col2(accumulate%x, this%c_Xh_GL%B, n_gl)
          call this%GLL_to_GL%map(work%x, accumulate%x, nel, this%Xh_GLL)
          call invcol2(work%x, this%coef%B, work%size())
       end if
       call field_sub2(fu, work)
 
       ! v
       call this%GLL_to_GL%map(fld_gl%x, this%v%x, nel, this%Xh_GL)
       call field_col3(accumulate, chi_gl, fld_gl)
       ! Evaluate term on GL and preempt the GLL premultiplication
       if (neko_bcknd_device .eq. 1) then
          call device_col2(accumulate%x_d, this%c_Xh_GL%B_d, n_gl)
          call this%GLL_to_GL%map(work%x, accumulate%x, nel, this%Xh_GLL)
          call device_invcol2(work%x_d, this%coef%B_d, work%size())
       else
          call col2(accumulate%x, this%c_Xh_GL%B, n_gl)
          call this%GLL_to_GL%map(work%x, accumulate%x, nel, this%Xh_GLL)
          call invcol2(work%x, this%coef%B, work%size())
       end if
       call field_sub2(fv, work)
 
       ! w
       call this%GLL_to_GL%map(fld_gl%x, this%w%x, nel, this%Xh_GL)
       call field_col3(accumulate, chi_gl, fld_gl)
       ! Evaluate term on GL and preempt the GLL premultiplication
       if (neko_bcknd_device .eq. 1) then
          call device_col2(accumulate%x_d, this%c_Xh_GL%B_d, n_gl)
          call this%GLL_to_GL%map(work%x, accumulate%x, nel, this%Xh_GLL)
          call device_invcol2(work%x_d, this%coef%B_d, work%size())
       else
          call col2(accumulate%x, this%c_Xh_GL%B, n_gl)
          call this%GLL_to_GL%map(work%x, accumulate%x, nel, this%Xh_GLL)
          call invcol2(work%x, this%coef%B, work%size())
       end if
       call field_sub2(fw, work)
 
       call this%scratch_GL%relinquish_field(temp_indices_gl)
    else
 
       call field_subcol3(fu, this%u, this%chi)
       call field_subcol3(fv, this%v, this%chi)
       call field_subcol3(fw, this%w, this%chi)
 
    end if
 
    call neko_scratch_registry%relinquish_field(temp_indices)
 
  end subroutine simple_brinkman_source_term_compute
 
end module simple_brinkman_source_term