adjoint_mixing_scalar_source_term.f90

Go to the documentation of this file.

 
!
! this is a such a dumb name
module adjoint_mixing_scalar_source_term
  use num_types, only : rp
  use field_list, only : field_list_t
  use field, only: field_t
  use registry, only: neko_registry
  use scratch_registry, only: neko_scratch_registry
  use json_module, only : json_file
  use time_state, only: time_state_t
  use json_utils, only: json_get, json_get_or_default
  use source_term, only : source_term_t
  use coefs, only : coef_t
  use field_math, only: field_add2s2, field_copy, field_cadd
  use mask_ops, only: mask_exterior_const, compute_masked_volume
  use point_zone, only: point_zone_t
  implicit none
  private
  public :: adjoint_mixing_scalar_source_term_allocate
 
  ! this will be the adjoint forcing from Casper's objective function
  ! TODO
  ! it actually isn't this. Infact, his is a surface integral on the outlet
  ! Which means we get strange BC's in our adjoint problem.
  ! This source term would be if we had a certain volume that we wanted more
  ! mixed
  ! the forcing is of the form:
  ! \f$ \phi - \phi_ref \f$
  ! ie, difference between it and the average.
  type, public, extends(source_term_t) :: adjoint_mixing_scalar_source_term_t
     type(field_t), pointer :: s => null()
     real(kind=rp) :: obj_scale
     real(kind=rp) :: phi_ref
     class(point_zone_t), pointer :: mask => null()
     logical :: if_mask
     real(kind=rp) :: mask_volume
   contains
     procedure, pass(this) :: init => &
          adjoint_mixing_scalar_source_term_init_from_json
     procedure, pass(this) :: init_from_components => &
          adjoint_mixing_scalar_source_term_init_from_components
     procedure, pass(this) :: free => adjoint_mixing_scalar_source_term_free
     procedure, pass(this) :: compute_ => &
          adjoint_mixing_scalar_source_term_compute
  end type adjoint_mixing_scalar_source_term_t
 
contains
  subroutine adjoint_mixing_scalar_source_term_allocate(obj)
    class(source_term_t), allocatable, intent(inout) :: obj
    allocate(adjoint_mixing_scalar_source_term_t::obj)
  end subroutine adjoint_mixing_scalar_source_term_allocate
 
  subroutine adjoint_mixing_scalar_source_term_init_from_json(this, &
       json, fields, coef, variable_name)
    class(adjoint_mixing_scalar_source_term_t), intent(inout) :: this
    type(json_file), intent(inout) :: json
    type(field_list_t), intent(in), target :: fields
    type(coef_t), intent(in), target :: coef
    character(len=*), intent(in) :: variable_name
 
 
  end subroutine adjoint_mixing_scalar_source_term_init_from_json
 
  subroutine adjoint_mixing_scalar_source_term_init_from_components(this, &
       f_s, s, obj_scale, phi_ref, mask, if_mask, coef, start_time, end_time)
    class(adjoint_mixing_scalar_source_term_t), intent(inout) :: this
    type(field_t), pointer, intent(in) :: f_s
    type(field_t), intent(in), target :: s
    real(kind=rp), intent(in) :: obj_scale
    real(kind=rp), intent(in) :: phi_ref
    class(point_zone_t), intent(in), target :: mask
    logical, intent(in) :: if_mask
    type(coef_t), intent(in) :: coef
    real(kind=rp), intent(in) :: start_time
    real(kind=rp), intent(in) :: end_time
 
    type(field_list_t) :: fields
 
    call this%free()
 
    ! this is copying the fluid source term init
    ! We package the fields for the source term to operate on in a field list.
    call fields%init(1)
    call fields%assign(1, f_s)
 
    call this%init_base(fields, coef, start_time, end_time)
    call fields%free()
 
    ! point everything in the correct places
    this%s => s
    this%obj_scale = obj_scale
    this%phi_ref = phi_ref
    this%if_mask = if_mask
 
    if (this%if_mask) then
       this%mask => mask
       this%mask_volume = compute_masked_volume(this%mask, coef)
    else
       this%mask_volume = coef%volume
    end if
 
  end subroutine adjoint_mixing_scalar_source_term_init_from_components
 
  subroutine adjoint_mixing_scalar_source_term_free(this)
    class(adjoint_mixing_scalar_source_term_t), intent(inout) :: this
 
    call this%free_base()
    nullify(this%s)
    nullify(this%mask)
 
  end subroutine adjoint_mixing_scalar_source_term_free
 
  subroutine adjoint_mixing_scalar_source_term_compute(this, time)
    class(adjoint_mixing_scalar_source_term_t), intent(inout) :: this
    type(time_state_t), intent(in) :: time
    type(field_t), pointer :: fs
    type(field_t), pointer :: work
    integer :: temp_indices(1)
 
 
    fs => this%fields%get(1)
 
    call neko_scratch_registry%request_field(work, temp_indices(1), .false.)
    ! \phi
    call field_copy(work, this%s)
    ! \phi - \phi_ref
    call field_cadd(work, -this%phi_ref)
    ! mask
    if (this%if_mask) then
       call mask_exterior_const(work, this%mask, 0.0_rp)
    end if
 
    ! append to RHS with scaling and mask volume
    call field_add2s2(fs, work, this%obj_scale / this%mask_volume)
    call neko_scratch_registry%relinquish_field(temp_indices)
 
 
  end subroutine adjoint_mixing_scalar_source_term_compute
 
end module adjoint_mixing_scalar_source_term