steepest_descent_cpu.f90

Go to the documentation of this file.

 
 
module steepest_descent_cpu
  use num_types, only: rp
  implicit none
  private
 
  public :: sd_direction_cpu, sd_update_move_limits_cpu, sd_update_design_cpu
 
contains
 
  subroutine sd_direction_cpu(s, x, xmin, xmax, n)
    integer, intent(in) :: n
    real(kind=rp), dimension(n), intent(inout) :: s
    real(kind=rp), dimension(n), intent(in) :: x
    real(kind=rp), intent(in) :: xmin, xmax
    integer :: i
 
    do i = 1, n
       s(i) = -s(i)
       if ((x(i) .ge. xmax .and. s(i) .gt. 0.0_rp) .or. &
            (x(i) .le. xmin .and. s(i) .lt. 0.0_rp)) then
          s(i) = 0.0_rp
       end if
    end do
 
  end subroutine sd_direction_cpu
 
  subroutine sd_update_move_limits_cpu(delta, x, x1, x2, dec, inc, dmin, &
       dmax, n)
    integer, intent(in) :: n
    real(kind=rp), dimension(n), intent(inout) :: delta
    real(kind=rp), dimension(n), intent(in) :: x, x1, x2
    real(kind=rp), intent(in) :: dec, inc, dmin, dmax
    real(kind=rp) :: d
    integer :: i
 
    do i = 1, n
       d = (x(i) - x1(i)) * (x1(i) - x2(i))
       if (d .lt. 0.0_rp) then
          delta(i) = dec * delta(i)
       else if (d .gt. 0.0_rp) then
          delta(i) = inc * delta(i)
       end if
       delta(i) = min(dmax, max(dmin, delta(i)))
    end do
 
  end subroutine sd_update_move_limits_cpu
 
  subroutine sd_update_design_cpu(x_new, x, s, delta, psi, smax, xmin, xmax, &
       n)
    integer, intent(in) :: n
    real(kind=rp), dimension(n), intent(out) :: x_new
    real(kind=rp), dimension(n), intent(in) :: x, s, delta
    real(kind=rp), intent(in) :: psi, smax, xmin, xmax
    integer :: i
 
    do i = 1, n
       x_new(i) = min(xmax, max(xmin, min(x(i) + delta(i), &
            max(x(i) - delta(i), x(i) + psi * (s(i) / smax)))))
    end do
 
  end subroutine sd_update_design_cpu
 
end module steepest_descent_cpu