objective_factory.f90

 
 
submodule(objective) objective_factory_mod
  use json_utils, only: json_get
  use utils, only: neko_type_error
 
  ! Import the objective function types
  use minimum_dissipation_objective, only: minimum_dissipation_objective_t
  use lube_term_objective, only: lube_term_objective_t
  use scalar_mixing_objective, only: scalar_mixing_objective_t
 
  implicit none
 
  character(len=25), parameter :: KNOWN_TYPES(3) = [ character(len=25) :: &
       "minimum_dissipation", &
       "scalar_mixing", &
       "lube_term"]
 
contains
 
  ! -------------------------------------------------------------------------- !
  ! Factory function
 
  module subroutine objective_factory(object, json, design, simulation)
    class(objective_t), allocatable, intent(inout) :: object
    type(json_file), intent(inout) :: json
    class(design_t), intent(in) :: design
    type(simulation_t), target, optional, intent(inout) :: simulation
    character(len=:), allocatable :: type
 
    if (allocated(object)) then
       call object%free()
       deallocate(object)
    end if
 
    call json_get(json, "type", type)
    select case (trim(type))
    case ("minimum_dissipation")
       allocate(minimum_dissipation_objective_t::object)
    case ("scalar_mixing")
       allocate(scalar_mixing_objective_t::object)
    case ("lube_term")
       allocate(lube_term_objective_t::object)
 
    case default
       call neko_type_error("Objective", type, KNOWN_TYPES)
    end select
 
    call object%init(json, design, simulation)
  end subroutine objective_factory
 
end submodule objective_factory_mod