advection_adjoint_fctry.f90

 
!
submodule(advection_adjoint) advection_adjoint_fctry
  use json_utils, only: json_get, json_get_or_default
  use utils, only: neko_error
 
  ! Advection and derivatives
  use adv_lin_dealias, only: adv_lin_dealias_t
  use adv_lin_no_dealias, only: adv_lin_no_dealias_t
 
contains
 
  module subroutine advection_adjoint_factory(object, json, coef, ulag, vlag, wlag, &
       dtlag, tlag, time_scheme, use_dummy, slag)
    class(advection_adjoint_t), allocatable, intent(inout) :: object
    type(json_file), intent(inout) :: json
    type(coef_t), intent(inout), target :: coef
    type(field_series_t), intent(in), target :: ulag, vlag, wlag
    real(kind=rp), intent(in), target :: dtlag(10)
    real(kind=rp), intent(in), target :: tlag(10)
    type(time_scheme_controller_t), intent(in), target :: time_scheme
    logical, optional, intent(in) :: use_dummy
    type(field_series_t), target, optional, intent(in) :: slag
 
    logical :: dealias, oifs
    real(kind=rp) :: ctarget
    integer :: lxd, order
 
    ! Free allocatables if necessary
    if (allocated(object)) then
       call object%free
       deallocate(object)
    end if
 
    if (present(use_dummy)) then
       if (use_dummy .eqv. .true.) then
          call neko_error("Dummy advection is not supported in the adjoint module.")
          return
       end if
    end if
 
    call json_get(json, 'dealias', dealias)
    call json_get(json, 'polynomial_order', order)
    call json_get_or_default(json, 'oifs', oifs, .false.)
 
    call json_get_or_default(json, 'dealiased_polynomial_order', &
         lxd, (3 * (order + 1)) / 2)
 
    call json_get_or_default(json, 'target_cfl', ctarget, 1.9_rp)
 
    if (oifs) then
       call neko_error("OIFS advection is not supported in the adjoint module.")
    else
       if (dealias) then
          allocate(adv_lin_dealias_t::object)
       else
          allocate(adv_lin_no_dealias_t::object)
       end if
    end if
 
    select type (adv => object)
    type is (adv_lin_dealias_t)
       call adv%init(lxd, coef)
    type is (adv_lin_no_dealias_t)
       call adv%init(coef)
       ! type is (adv_oifs_t)
       !    if (present(slag)) then
       !       call adv%init(lxd, coef, ctarget, ulag, vlag, wlag, &
       !            dtlag, tlag, time_scheme, slag)
       !    else
       !       call adv%init(lxd, coef, ctarget, ulag, vlag, wlag, &
       !            dtlag, tlag, time_scheme)
       !    end if
    end select
 
  end subroutine advection_adjoint_factory
 
 
end submodule advection_adjoint_fctry