adjoint_scalar_pnpn_bc_fctry.f90

 
!
submodule(adjoint_scalar_pnpn) adjoint_scalar_pnpn_bc_fctry
  use dirichlet, only : dirichlet_t
  use neumann, only : neumann_t
  use user_intf, only : user_t
  use utils, only : neko_type_error
  use field_dirichlet, only : field_dirichlet_t
  implicit none
 
  ! List of all possible types created by the boundary condition factories
  character(len=25) :: ADJOINT_SCALAR_KNOWN_BCS(4) = [character(len=25) :: &
       "dirichlet", &
       "user_pointwise", &
       "user", &
       "neumann"]
 
contains
 
  module subroutine adjoint_bc_factory(object, scheme, json, coef, user)
    class(bc_t), pointer, intent(inout) :: object
    type(adjoint_scalar_pnpn_t), intent(in) :: scheme
    type(json_file), intent(inout) :: json
    type(coef_t), intent(in) :: coef
    type(user_t), intent(in) :: user
    character(len=:), allocatable :: type
    integer :: i
    integer, allocatable :: zone_indices(:)
 
    call json_get(json, "type", type)
 
    select case (trim(type))
    case ("user")
       allocate(field_dirichlet_t::object)
       select type (obj => object)
       type is (field_dirichlet_t)
          obj%update => user%dirichlet_conditions
          ! Add the name of the dummy field in the bc, matching the scalar
          ! solved for.
          call json%add("field_name", scheme%s_adj%name)
       end select
    case ("dirichlet")
       allocate(dirichlet_t::object)
    case ("neumann")
       allocate(neumann_t::object)
    case default
       call neko_type_error("scalar_pnpn boundary conditions", type, &
            ADJOINT_SCALAR_KNOWN_BCS)
    end select
 
    call json_get(json, "zone_indices", zone_indices)
    call object%init(coef, json)
    do i = 1, size(zone_indices)
       call object%mark_zone(coef%msh%labeled_zones(zone_indices(i)))
    end do
    call object%finalize()
 
  end subroutine adjoint_bc_factory
 
 
end submodule adjoint_scalar_pnpn_bc_fctry