adjoint_fluid_pnpn_bc_fctry.f90

 
!
submodule(adjoint_fluid_pnpn) adjoint_fluid_pnpn_bc_fctry
  use user_intf, only: user_t
  use utils, only: neko_type_error
  use field_dirichlet, only: field_dirichlet_t
  use inflow, only: inflow_t
  use blasius, only: blasius_t
  use dirichlet, only: dirichlet_t
  use dong_outflow, only: dong_outflow_t
  use symmetry_aligned, only: symmetry_aligned_t
  use non_normal_aligned, only: non_normal_aligned_t
  use zero_dirichlet, only: zero_dirichlet_t
  use shear_stress, only: shear_stress_t
  use wall_model_bc, only: wall_model_bc_t
  use field_dirichlet_vector, only: field_dirichlet_vector_t
  implicit none
 
  ! List of all possible types created by the boundary condition factories
  character(len=25) :: ADJOINT_FLUID_PNPN_KNOWN_BCS(13) = &
       [character(len=25) :: &
       "symmetry", &
       "velocity_value", &
       "no_slip", &
       "outflow", &
       "normal_outflow", &
       "outflow+dong", &
       "normal_outflow+dong", &
       "shear_stress", &
       "user_velocity", &
       "user_pressure", &
       "blasius_profile", &
       "user_velocity_pointwise", &
       "wall_model"]
 
contains
 
  module subroutine pressure_bc_factory(object, scheme, json, coef, user)
    class(bc_t), pointer, intent(inout) :: object
    type(adjoint_fluid_pnpn_t), intent(in) :: scheme
    type(json_file), intent(inout) :: json
    type(coef_t), target, intent(in) :: coef
    type(user_t), target, intent(in) :: user
    character(len=:), allocatable :: type
    integer :: i, j, k
    integer, allocatable :: zone_indices(:)
 
    call json_get(json, "type", type)
 
    select case (trim(type))
    case ("outflow", "normal_outflow")
       allocate(zero_dirichlet_t::object)
 
    case ("outflow+dong", "normal_outflow+dong")
       allocate(dong_outflow_t::object)
 
    case ("user_pressure")
       allocate(field_dirichlet_t::object)
       select type (obj => object)
       type is (field_dirichlet_t)
          obj%update => user%dirichlet_conditions
          call json%add("field_name", scheme%p_adj%name)
       end select
 
    case default
       do i = 1, size(adjoint_fluid_pnpn_known_bcs)
          if (trim(type) .eq. trim(adjoint_fluid_pnpn_known_bcs(i))) return
       end do
       call neko_type_error("adjoint_fluid_pnpn boundary conditions", type, &
            ADJOINT_FLUID_PNPN_KNOWN_BCS)
    end select
 
    call json_get(json, "zone_indices", zone_indices)
    call object%init(coef, json)
 
    do i = 1, size(zone_indices)
       call object%mark_labeled_zone(zone_indices(i))
    end do
    call object%finalize()
 
    ! All pressure bcs are currently strong, so for all of them we
    ! mark with value 1 in the mesh
    do i = 1, size(zone_indices)
       do j = 1, scheme%msh%nelv
          do k = 1, 2 * scheme%msh%gdim
             if (scheme%msh%facet_type(k,j) .eq. -zone_indices(i)) then
                scheme%msh%facet_type(k, j) = 1
             end if
          end do
       end do
    end do
  end subroutine pressure_bc_factory
 
  module subroutine velocity_bc_factory(object, scheme, json, coef, user)
    class(bc_t), pointer, intent(inout) :: object
    type(adjoint_fluid_pnpn_t), intent(in) :: scheme
    type(json_file), intent(inout) :: json
    type(coef_t), target, intent(in) :: coef
    type(user_t), target, intent(in) :: user
    character(len=:), allocatable :: type
    integer :: i, j, k
    integer, allocatable :: zone_indices(:)
 
    call json_get(json, "type", type)
 
    select case (trim(type))
    case ("symmetry")
       allocate(symmetry_aligned_t::object)
    case ("velocity_value")
       allocate(inflow_t::object)
    case ("no_slip")
       allocate(zero_dirichlet_t::object)
    case ("normal_outflow", "normal_outflow+dong")
       allocate(non_normal_aligned_t::object)
    case ("blasius_profile")
       allocate(blasius_t::object)
    case ("shear_stress")
       allocate(shear_stress_t::object)
    case ("wall_model")
       allocate(wall_model_bc_t::object)
       ! Kind of hack, but maybe OK? The thing is, we need the nu for
       ! initing the wall model, and forcing the user duplicate that there
       ! would be a nightmare.
       !  call json%add("nu", scheme%mu / scheme%rho)
 
    case ("user_velocity")
       allocate(field_dirichlet_vector_t::object)
       select type (obj => object)
       type is (field_dirichlet_vector_t)
          obj%update => user%dirichlet_conditions
       end select
 
       ! case ("user_velocity_pointwise")
       !  allocate(usr_inflow_t::object)
       !  select type (obj => object)
       !    type is (usr_inflow_t)
       !     call obj%set_eval(user%adjoint_user_if)
       !     call obj%validate()
       !  end select
 
    case default
       do i = 1, size(adjoint_fluid_pnpn_known_bcs)
          if (trim(type) .eq. trim(adjoint_fluid_pnpn_known_bcs(i))) return
       end do
       call neko_type_error("adjoint_fluid_pnpn boundary conditions", type, &
            ADJOINT_FLUID_PNPN_KNOWN_BCS)
    end select
 
    call json_get(json, "zone_indices", zone_indices)
    call object%init(coef, json)
    do i = 1, size(zone_indices)
       call object%mark_labeled_zone(zone_indices(i))
    end do
    call object%finalize()
 
    ! Exclude these two because they are bcs for the residual, not velocity
    if (trim(type) .ne. "normal_outflow" .and. &
         trim(type) .ne. "normal_outflow+dong") then
       do i = 1, size(zone_indices)
          do j = 1, scheme%msh%nelv
             do k = 1, 2 * scheme%msh%gdim
                if (scheme%msh%facet_type(k,j) .eq. -zone_indices(i)) then
                   scheme%msh%facet_type(k, j) = 2
                end if
             end do
          end do
       end do
    end if
  end subroutine velocity_bc_factory
 
end submodule adjoint_fluid_pnpn_bc_fctry