design_factory.f90

 
 
submodule(design) design_factory_mod
  use json_utils, only: json_get
  use utils, only: neko_type_error
 
  ! Import the design function types
  use brinkman_design, only: brinkman_design_t
  use simple_design, only: simple_design_t
 
  implicit none
 
  character(len=25), parameter :: KNOWN_TYPES(2) = [ character(len=25) :: &
       "brinkman", &
       "simple"]
 
contains
 
  ! -------------------------------------------------------------------------- !
  ! Factory function
 
  module subroutine design_factory(object, parameters, simulation)
    class(design_t), allocatable, intent(inout) :: object
    type(json_file), intent(inout) :: parameters
    type(simulation_t), intent(inout), optional :: simulation
    character(len=:), allocatable :: type
 
    if (allocated(object)) then
       call object%free()
       deallocate(object)
    end if
 
    call json_get(parameters, "type", type)
    select case (trim(type))
    case ("brinkman")
       allocate(brinkman_design_t::object)
    case ("simple")
       allocate(simple_design_t::object)
 
    case default
       call neko_type_error("design", type, KNOWN_TYPES)
    end select
 
    if (present(simulation)) then
       call object%init_from_json_sim(parameters, simulation)
    else
       call object%init_from_json(parameters)
    end if
  end subroutine design_factory
 
end submodule design_factory_mod